blob: 8c368df2c9edb0365e16fdb2e3eb65ffe3752723 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Thomas Dziedzic < gostrc at gmail >
# Contributor: James Campos <james.r.campos@gmail.com>
# Contributor: BlackEagle < ike DOT devolder AT gmail DOT com >
# Contributor: Dongsheng Cai <dongsheng at moodle dot com>
# Contributor: Masutu Subric <masutu.arch at googlemail dot com>
# Contributor: TIanyi Cui <tianyicui@gmail.com>
pkgname=nodejs
pkgver=0.4.9
pkgrel=1
pkgdesc='Evented I/O for V8 javascript'
arch=('i686' 'x86_64')
url='http://nodejs.org/'
license=('MIT')
depends=('python2')
makedepends=('curl') # curl used for check()
optdepends=('openssl: TLS support')
conflicts=('nodejs-unstable')
source=("http://nodejs.org/dist/node-v${pkgver}.tar.gz")
sha256sums=('f231ea6d19ea9ea4c7f8e7ff5061e7d301f1635bec7ed0ff1eef2512576ea442')
build() {
cd node-v${pkgver}
# python2 fix
for file in $(find . -name '*.py' -print) wscript tools/waf-light tools/node-waf
do
sed -i 's_^#!.*/usr/bin/python_#!/usr/bin/python2_' ${file}
sed -i 's_^#!.*/usr/bin/env.*python_#!/usr/bin/env python2_' ${file}
done
sed -i "s|cmd_R = 'python |cmd_R = 'python2 |" wscript
sed -i "s|python |python2 |" Makefile
./configure \
--prefix=/usr
make
}
check() {
cd node-v${pkgver}
# only 1 test should fail afaik
# === release test-http-dns-fail ===
# https://github.com/joyent/node/issues/703
make test || true
}
package() {
cd node-v${pkgver}
make DESTDIR=${pkgdir} install
install -D -m644 LICENSE \
${pkgdir}/usr/share/licenses/nodejs/LICENSE
}
# vim:set ts=2 sw=2 et:
|
