blob: 24effb6a2b90bd0c6f3dcc0995021d872275f443 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# $Id: PKGBUILD 114634 2014-07-02 10:45:58Z svenstaro $
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: Lone_Wolf <lonewolf@xs4all.nl>
pkgname=oolite
pkgver=1.80
pkgrel=1
pkgdesc="A space-sim based on the classic Elite"
arch=('i686' 'x86_64')
url="http://oolite-linux.berlios.de"
license=('GPL2')
depends=('gnustep-gui' 'sdl_mixer' 'glu' 'espeak' 'nspr' 'python2' 'icu' 'gnustep-base' 'openal')
makedepends=('gcc-objc' 'gnustep-make' 'curl' 'zip' 'mesa')
#options=(makeflags)
source=(oolite
"https://github.com/OoliteProject/oolite/releases/download/1.80b/oolite-source-${pkgver}.tar.bz2")
md5sums=('b182976fade9b64a3b3702e2a8c72bf0'
'ded6afaf83f97624122c2dd999319166')
build() {
cd oolite-source-${pkgver}
unset CPPFLAGS
sed -i '/void png_error/d' src/Core/Materials/OOPNGTextureLoader.m
sed -i "/ADDITIONAL_OBJCFLAGS/s/=/= -fobjc-exceptions/" GNUmakefile
make -f Makefile release
}
package() {
cd oolite-source-${pkgver}
mkdir -p ${pkgdir}/usr/bin
mkdir -p ${pkgdir}/usr/share/{oolite,applications,pixmaps,doc/oolite}
cp -r oolite.app/* ${pkgdir}/usr/share/oolite/
#install shellscript and icon
install -D -m755 ../oolite ${pkgdir}/usr/bin/oolite
install -D -m644 installers/FreeDesktop/oolite-icon.png ${pkgdir}/usr/share/pixmaps/oolite-icon.png
# copy .desktop file
install -D -m644 installers/FreeDesktop/oolite.desktop ${pkgdir}/usr/share/applications/oolite.desktop
# documentation
install -D -m644 Doc/AdviceForNewCommanders.pdf Doc/OoliteReadMe.pdf Doc/OoliteRS.pdf ${pkgdir}/usr/share/doc/oolite/
}
# vim:set ts=2 sw=2 et:
|
