blob: fc56c82117679329283b9db7454f3efbe86a7fdc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# $Id: PKGBUILD 94175 2013-07-15 22:55:05Z svenstaro $
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
pkgname=openshadinglanguage
pkgver=1.3.3
pkgrel=3
pkgdesc="Advanced shading language for production GI renderers"
arch=(i686 x86_64)
url="https://github.com/imageworks/OpenShadingLanguage"
license=('custom')
depends=('boost-libs' 'openimageio' 'openexr' 'intel-tbb' 'freetype2' 'libpng' 'libtiff' 'llvm')
makedepends=('boost' 'cmake' 'clang')
source=(https://github.com/imageworks/OpenShadingLanguage/archive/Release-${pkgver}.tar.gz)
md5sums=('17aaa01987963220e164522c29281f14')
build() {
cd OpenShadingLanguage-Release-$pkgver
cd src
[[ -d build ]] && rm -r build
mkdir build && cd build
cmake \
-DCMAKE_INSTALL_PREFIX=/usr \
-DLLVM_STATIC=1 \
..
make
}
package() {
cd OpenShadingLanguage-Release-$pkgver/src/build
make DESTDIR="$pkgdir/" install
mkdir -p "$pkgdir"/usr/share/OSL/
mkdir -p "$pkgdir"/usr/share/licenses/$pkgname
mv "$pkgdir"/usr/LICENSE "$pkgdir"/usr/share/licenses/$pkgname # TODO: Tell upstream about this shit
mv "$pkgdir"/usr/{CHANGES,README.md,INSTALL} "$pkgdir"/usr/share/OSL/
mv "$pkgdir"/usr/doc "$pkgdir"/usr/share/OSL/doc
mv "$pkgdir"/usr/shaders "$pkgdir"/usr/share/OSL/shaders
}
# vim:set ts=2 sw=2 et:
|
