blob: 950a3d99274cd25b3f13b18ef67eaaf8603d1ccd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
|
# $Id: PKGBUILD 69216 2012-04-10 05:27:08Z jconder $
# Maintainer: Jonathan Conder <jonno.conder@gmail.com>
pkgbase='packagekit'
pkgname=('packagekit' 'packagekit-qt' 'packagekit-qt2' 'packagekit-python')
pkgver=0.6.21
pkgrel=3
pkgdesc="A system designed to make installation and updates of packages easier."
arch=('i686' 'x86_64')
url="http://www.packagekit.org"
license=('GPL')
makedepends=('dbus-glib' 'gobject-introspection' 'gtk-doc' 'intltool'
'networkmanager' 'pacman' 'pm-utils' 'polkit' 'python2' 'qt'
'shared-mime-info' 'sqlite' 'udev')
options=('!libtool')
source=("http://www.packagekit.org/releases/PackageKit-$pkgver.tar.xz"
'alpm.patch')
sha256sums=('68e5d4d07adf50b1fae6cbc0963555345ba7fc12d86d3e3387874547a5448b8e'
'ab6a9be1741aba6972f3327ac625b802e9404e21fe60ca0919a440e8ac9df965')
build() {
cd "$srcdir/PackageKit-$pkgver"
patch -Np1 -i "$srcdir/alpm.patch"
sed -i 's@SUBDIRS = test@SUBDIRS =@' 'backends/Makefile.in'
sed -i 's@python @python2 @' 'lib/python/packagekit/Makefile.in'
sed -i 's@bin/python@bin/python2@' 'lib/python/packagekit/'*.py
export PYTHON=/usr/bin/python2
# TODO: remove when upstream is patched
autoreconf
./configure --prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--libexecdir=/usr/lib/PackageKit \
--enable-strict \
--disable-static \
--disable-gtk-doc \
--disable-tests \
--disable-local \
--disable-browser-plugin \
--disable-gstreamer-plugin \
--disable-gtk-module \
--disable-command-not-found \
--disable-cron \
--disable-debuginfo-install \
--enable-pm-utils \
--disable-dummy \
--enable-alpm \
--with-default-backend=alpm
make -s
}
package_packagekit() {
backup=('var/lib/PackageKit/transactions.db'
'etc/PackageKit/alpm.d/pacman.conf'
'etc/PackageKit/alpm.d/repos.list')
depends=('dbus-glib' 'pacman>=4.0.0' 'pacman<4.1.0' 'polkit'
'shared-mime-info' 'sqlite' 'udev')
optdepends=('networkmanager')
install='packagekit.install'
cd "$srcdir/PackageKit-$pkgver"
make DESTDIR="$pkgdir" install
rm -rf "$pkgdir/usr/include/PackageKit/packagekit-qt"*
rm -rf "$pkgdir/usr/lib/libpackagekit-qt"*
rm -rf "$pkgdir/usr/lib/pkgconfig/packagekit-qt"*
rm -rf "$pkgdir/usr/share/cmake"
rm -rf "$pkgdir/usr/lib/python"*
rm -rf "$pkgdir/usr/share/PackageKit/website"
mkdir -p "$pkgdir/usr/share/bash-completion/completions"
mv "$pkgdir/etc/bash_completion.d/pk-completion.bash" \
"$pkgdir/usr/share/bash-completion/completions/pkcon"
touch "$pkgdir/var/log/PackageKit"
}
package_packagekit-qt() {
depends=('packagekit' 'qt')
pkgdesc=('Qt bindings for PackageKit')
cd "$srcdir/PackageKit-$pkgver/lib/packagekit-qt"
make DESTDIR="$pkgdir" install
}
package_packagekit-qt2() {
depends=('packagekit' 'qt')
pkgdesc=('Qt bindings for PackageKit')
cd "$srcdir/PackageKit-$pkgver/lib/packagekit-qt2"
make DESTDIR="$pkgdir" install
}
package_packagekit-python() {
depends=('packagekit' 'python2')
pkgdesc=('Python bindings for PackageKit')
cd "$srcdir/PackageKit-$pkgver/lib/python"
make DESTDIR="$pkgdir" install
}
|
