blob: a8ae351211e884bac2dfdbdbe63d4b52eeb04bed (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id: PKGBUILD 109398 2014-04-14 14:00:16Z foutrelis $
# Contributor: Vasco Costa <vasco dot costa at geekslot dot com>
# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
pkgname=pbzip2
pkgver=1.1.9
pkgrel=1
pkgdesc="Parallel implementation of the bzip2 block-sorting file compressor"
arch=('i686' 'x86_64')
url="http://compression.ca/pbzip2/"
license=('BSD')
depends=('bzip2' 'gcc-libs')
source=(https://launchpad.net/$pkgname/1.1/$pkgver/+download/$pkgname-$pkgver.tar.gz{,.asc})
sha256sums=('bd421be03e6e24a24a121ba2355bfd11571356a25ee64fcfa76330750ec5f9c4'
'SKIP')
build() {
cd "$srcdir/$pkgname-$pkgver"
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make PREFIX="$pkgdir/usr" install
# Fix location of man pages
install -d "$pkgdir/usr/share"
mv "$pkgdir/usr/man" "$pkgdir/usr/share"
# Symlinks for useful shortcuts
ln -sf pbzip2 "$pkgdir/usr/bin/pbunzip2"
ln -sf pbzip2 "$pkgdir/usr/bin/pbzcat"
# License
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}
# vim:set ts=2 sw=2 et:
|
