blob: 183a589b7084ae9dd5dcbfeb490406417da76ce0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# $Id: PKGBUILD 116171 2014-07-23 14:17:10Z fyan $
# Maintainer: Felix Yan <felixonmars@gmail.com>
# Contributor: TDY <tdy@archlinux.info>
# Contributor: Olaf Leidinger <leidola@newcon.de>
pkgname=perl-gtk2-imageview
pkgver=0.05
pkgrel=4
pkgdesc="Perl bindings to the GtkImageView image viewer widget"
arch=('i686' 'x86_64')
url="http://search.cpan.org/dist/Gtk2-ImageView/"
license=('LGPL3')
depends=('cairo-perl' 'glib-perl' 'gtk2-perl' 'gtkimageview')
makedepends=('perl-extutils-depends' 'perl-extutils-pkgconfig')
checkdepends=('perl-test-pod' 'xorg-server-xvfb')
options=('!emptydirs')
source=("http://search.cpan.org/CPAN/authors/id/R/RA/RATCLIFFE/Gtk2-ImageView-$pkgver.tar.gz")
md5sums=('7c961071b347b6a64b8351fdd87ec4c0')
build() {
cd "$srcdir/Gtk2-ImageView-$pkgver"
PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
make
}
check() {
cd "$srcdir/Gtk2-ImageView-$pkgver"
xvfb-run -a -s "-extension GLX -screen 0 1280x1024x24" make test
}
package() {
cd "$srcdir/Gtk2-ImageView-$pkgver"
make DESTDIR="$pkgdir" install
}
|
