blob: 9bbf6f5cc5a243d56a687331dbf8ba724456500a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# $Id: PKGBUILD 97046 2013-09-11 13:42:10Z fyan $
# Maintainer: Felix Yan <felixonmars@gmail.com>
# Contributor: grimsock <lord.grimsock at gmail dot com>
# Contributor: Dieter Plaetinck <dieter@plaetinck.be>
# Contributor: Vladimir Chizhov <jagoterr@gmail.com>
# Contributor: Henry Tang <henryykt@gmail.com>
pkgname=phantomjs
pkgver=1.9.2
pkgrel=1
pkgdesc="Headless WebKit with JavaScript API"
url="http://www.phantomjs.org/"
license=('BSD' 'LGPL' 'MIT')
arch=('i686' 'x86_64')
depends=('gstreamer0.10-base' 'fontconfig' 'freetype2')
makedepends=('unzip')
source=("http://phantomjs.googlecode.com/files/${pkgname}-${pkgver}-source.zip")
noextract=("${pkgname}-${pkgver}-source.zip")
build() {
# workaround for https://code.google.com/p/libarchive/issues/detail?id=271
# cd $srcdir/$pkgname-$pkgver
unzip ${pkgname}-${pkgver}-source.zip
cd $pkgname-$pkgver
# workaround for http://code.google.com/p/phantomjs/issues/detail?id=635
sed -i 's/QMAKE_LFLAGS+=-fuse-ld=gold/#QMAKE_LFLAGS+=-fuse-ld=gold/' src/qt/src/3rdparty/webkit/Source/common.pri
./build.sh --confirm --qt-config "-no-rpath"
}
package() {
install -Dm755 "$srcdir/$pkgname-$pkgver/bin/phantomjs" "$pkgdir/usr/bin/phantomjs"
mkdir -p "$pkgdir/usr/share/$pkgname"
cp -r "$srcdir/$pkgname-$pkgver/examples" "$pkgdir/usr/share/$pkgname"/
install -Dm644 "$srcdir/$pkgname-$pkgver/LICENSE.BSD" "$pkgdir/usr/share/licenses/$pkgname/LICENSE.BSD"
install -Dm644 "$srcdir/$pkgname-$pkgver/third-party.txt" "$pkgdir/usr/share/licenses/$pkgname/third-party.txt"
}
sha512sums=('ada4010a1ba43950f25bcf42bc41f158c8dc91320edff18efece68c69cd16d1246512fbd66e2dcbe9d0ecd71d8587252570072e2499ec9dfce0ac871c0ce2720')
|
