blob: f9594715db85dc24aa610e0692ad7dc09f797c93 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# $Id: PKGBUILD 107797 2014-03-19 18:14:08Z flexiondotorg $
# Maintainer : Martin Wimpress <code@flexion.org>
pkgname=pluma
pkgver=1.8.0
pkgrel=3
pkgdesc="A powerful text editor for MATE"
url="http://mate-desktop.org"
arch=('i686' 'x86_64')
license=('GPL')
depends=('desktop-file-utils' 'enchant' 'gtk2' 'iso-codes' 'libsm'
'mate-desktop' 'mate-dialogs' 'pygtksourceview2' 'python2-gobject2')
makedepends=('mate-common' 'perl-xml-parser' 'yelp-tools')
optdepends=('yelp: for reading MATE help documents')
replaces=('mate-text-editor')
provides=('mate-text-editor')
conflicts=('mate-text-editor')
groups=('mate-extra')
source=("http://pub.mate-desktop.org/releases/1.8/${pkgname}-${pkgver}.tar.xz")
sha1sums=('858e3edaee698b3f99189d3285061ab56b21828c')
install=${pkgname}.install
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
sed -i 's/python/python2/' plugins/externaltools/data/switch-c.tool.in
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
PYTHON=/usr/bin/python2 ./configure \
--prefix=/usr \
--libexecdir=/usr/lib/${pkgname} \
--with-gtk=2.0 \
--enable-gtk-doc \
--enable-python
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
}
|