blob: 5eaf8a9915457415a557d3c58c965a606b605350 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# $Id: PKGBUILD 65625 2012-02-21 12:15:55Z ttopper $
# Maintainer: Thorsten Töpper <atsutane-tu@freethoughts.de>
# Contributor: Jelle van der Waa <jelle vdwaa nl>
# Contributor: Thomas Holmquist <thomas@vorget.com>
# Contributor: Jan Boehringer <ja(a)bm-boehringer.de>
# Contributor: Alex Griffin <griffin.aj(a)gmail.com>
pkgname=polipo
pkgver=1.0.4.1
pkgrel=2
pkgdesc="A small and fast caching web proxy."
arch=('i686' 'x86_64')
url="http://www.pps.jussieu.fr/~jch/software/polipo/"
license=('GPL')
depends=('bash')
makedepends=(texinfo)
install=polipo.install
source=(http://freehaven.net/~chrisd/polipo/polipo-$pkgver.tar.gz
polipo.cron polipo.rc.d)
md5sums=('bfc5c85289519658280e093a270d6703'
'bac0e1a871964c931eb5f7a369b3243c'
'443e442f7071e31dbd53fc9d810a2c3e')
conflicts=('polipo-git' 'polipo-darcs')
build() {
cd "$srcdir/$pkgname-$pkgver"
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make PREFIX="$pkgdir/usr" \
MANDIR="$pkgdir/usr/share/man" \
INFODIR="$pkgdir/usr/share/info" \
LOCAL_ROOT="$pkgdir/usr/share/polipo/www" \
DISK_CACHE_ROOT="$pkgdir/var/cache/polipo" \
install
# install config files
install -Dm 644 config.sample $pkgdir/etc/polipo/config.sample
install -Dm 644 forbidden.sample $pkgdir/etc/polipo/forbidden.sample
# install license
install -Dm644 COPYING $pkgdir/usr/share/licenses/polipo/LICENSE
# install daemon scripts / cron
install -Dm 755 $srcdir/polipo.rc.d $pkgdir/etc/rc.d/polipo
install -Dm 755 $srcdir/polipo.cron $pkgdir/usr/share/polipo/polipo.cron
}
# vim:set ts=2 sw=2 et:
|
