blob: 1feb6aedd6b3c502be1a30a52a83be49256903c6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# $Id: PKGBUILD 109419 2014-04-14 18:46:41Z jelle $
# Maintainer: Thorsten Töpper <atsutane-tu@freethoughts.de>
# Contributor: Jelle van der Waa <jelle vdwaa nl>
# Contributor: Daniel Micay <danielmicay@gmail.com>
# Contributor: Thomas Holmquist <thomas@vorget.com>
# Contributor: Jan Boehringer <ja(a)bm-boehringer.de>
# Contributor: Alex Griffin <griffin.aj(a)gmail.com>
pkgname=polipo
pkgver=1.1.0
pkgrel=1
pkgdesc="A small and fast caching web proxy."
arch=('i686' 'x86_64')
url="http://www.pps.jussieu.fr/~jch/software/polipo/"
license=('GPL')
depends=('bash')
makedepends=('texinfo')
install=polipo.install
source=("http://www.pps.univ-paris-diderot.fr/~jch/software/files/polipo/polipo-$pkgver.tar.gz"
"polipo.service")
md5sums=('55c6fc19e8d484997f223a56f0bd26ca'
'3861a067f6cdd2b8afcee1de97678902')
build() {
cd "$srcdir/$pkgname-$pkgver"
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make PREFIX="$pkgdir/usr" \
MANDIR="$pkgdir/usr/share/man" \
INFODIR="$pkgdir/usr/share/info" \
LOCAL_ROOT="$pkgdir/usr/share/polipo/www" \
DISK_CACHE_ROOT="$pkgdir/var/cache/polipo" \
install
# install config files
install -Dm 644 config.sample "$pkgdir/etc/polipo/config.sample"
install -Dm 644 forbidden.sample "$pkgdir/etc/polipo/forbidden.sample"
# install license
install -Dm644 COPYING "$pkgdir/usr/share/licenses/polipo/LICENSE"
# install systemd service
install -Dm 644 "$srcdir/polipo.service" "$pkgdir/usr/lib/systemd/system/polipo.service"
install -dm 700 -o 185 -g 185 "$pkgdir/var/cache/polipo"
}
# vim:set ts=2 sw=2 et:
|
