blob: d8ee40a2541dc34b9ea92ffe5b6c4340cdb254f0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# $Id: PKGBUILD 100035 2013-10-31 11:20:48Z arodseth $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Jan Steffens <heftig@archlinux.org>
pkgname=powerdns-recursor
pkgver=3.5.3
pkgrel=2
pkgdesc='Resolving DNS server'
url='https://www.powerdns.com/'
license=('GPL')
arch=('x86_64' 'i686')
depends=('gcc-libs' 'lua51')
makedepends=('boost')
replaces=('pdns-recursor')
provides=('pdns-recursor')
conflicts=('pdns-recursor')
backup=('etc/powerdns/recursor.conf')
source=("http://downloads.powerdns.com/releases/pdns-recursor-$pkgver.tar.bz2"
'pdns-recursor.service')
sha256sums=('192c0b47a1cfcdccaa88d70fd33766a4c381f4223f966416f15e169df5d58eaa'
'd4f545e85dffa86bf23c89ff0f352c74ec3524dfc53871f129656299222e4fba')
build() {
make -C "pdns-recursor-$pkgver" -j1 LUA=1 \
LUA_CPPFLAGS_CONFIG="$(pkg-config --cflags lua5.1)" \
LUA_LIBS_CONFIG="$(pkg-config --libs lua5.1)"
}
package() {
cd "pdns-recursor-$pkgver"
make SBINDIR="/usr/bin" DESTDIR="$pkgdir" install
mv "$pkgdir/etc/powerdns/recursor.conf-dist" \
"$pkgdir/etc/powerdns/recursor.conf"
rm -r "$pkgdir/etc/init.d"
install -Dm644 "$srcdir/pdns-recursor.service" \
"$pkgdir/usr/lib/systemd/system/pdns-recursor.service"
}
# vim:set ts=2 sw=2 et:
|
