blob: 90bf625f02b298930748087e5e6421a4f99fc644 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# $Id: PKGBUILD 87227 2013-03-28 19:33:14Z stephane $
# Maintainer: Stéphane Gaudreault <stephane@archlinux.org>
pkgbase=python-pyproj
pkgname=('python-pyproj' 'python2-pyproj')
pkgver=1.9.3
pkgrel=1
pkgdesc="Python interfaces to PROJ.4 library"
arch=('i686' 'x86_64')
url="http://code.google.com/p/pyproj"
license=('custom')
source=(http://pyproj.googlecode.com/files/pyproj-${pkgver}.tar.gz)
makedepends=('python' 'python2')
sha1sums=('3f290241e113ea63d0487a48e7e054cc1c3e19f8')
build() {
cd "${srcdir}"
cp -a pyproj-${pkgver}{,-python2}
# Build python 3 module
cd pyproj-${pkgver}
python3 setup.py build
# Build python 2 module
cd ../pyproj-${pkgver}-python2
python2 setup.py build
}
package_python-pyproj() {
depends=('proj' 'python>=3.3')
cd "${srcdir}"/pyproj-${pkgver}
python3 setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build
install -dm755 "${pkgdir}"/usr/share/licenses/${pkgname}
install -m644 LICENSE_proj4 "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}
package_python2-pyproj() {
depends=('proj' 'python2>=2.7')
replaces=('pyproj')
cd "${srcdir}"/pyproj-${pkgver}-python2
python2 setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build
install -dm755 "${pkgdir}"/usr/share/licenses/${pkgname}
install -m644 LICENSE_proj4 "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}
|
