blob: 52ac67aa9c739321d2b23850953a3134cae41dc0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# $Id: PKGBUILD 115392 2014-07-10 08:30:26Z schiv $
# Maintainer : Ray Rashif <schiv@archlinux.org>
# Maintainer : speps <speps at aur dot archlinux dot org>
# Contributor: Philipp Überbacher <hollunder at gmx dot at>
pkgname=qtractor
pkgver=0.6.2
pkgrel=1
pkgdesc="Audio/MIDI multitrack sequencer"
arch=('i686' 'x86_64')
url="http://qtractor.sourceforge.net/"
license=('GPL')
depends=('qt4' 'suil' 'lilv' 'libmad' 'liblo>=0.28'
'rubberband' 'shared-mime-info')
makedepends=('ladspa' 'dssi')
optdepends=('dssi-vst: win32 VST support')
install="$pkgname.install"
source=("http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz")
md5sums=('68d91105fbee6d711bc317f1fc6164d0')
prepare() {
cd $pkgname-$pkgver
# do not look for /usr/lib64/lv2
# prevent to load lv2 plugins twice
sed -i '/__x86_64__/,/#endif/d' src/qtractorPlugin.cpp
# force qt4
export ac_qmake=/usr/bin/qmake-qt4 \
ac_moc=/usr/bin/moc-qt4 \
ac_uic=/usr/bin/uic-qt4 \
ac_lupdate=/usr/bin/lupdate-qt4 \
ac_lrelease=/usr/bin/lrelease-qt4 \
QMAKE=qmake-qt4
}
build() {
cd "$pkgname-$pkgver"
./configure --prefix=/usr
make
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
}
# vim:set ts=2 sw=2 et:
|
