blob: 978250cf8f92c0a265e9237dc6723d2acf54522f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id: PKGBUILD 73047 2012-06-29 15:41:01Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Jan-Erik Rediger <badboy at archlinux dot us>
# Contributor: nofxx <x@<nick>.com>
pkgname=redis
pkgver=2.4.15
pkgrel=1
pkgdesc="Advanced key-value store"
arch=('i686' 'x86_64')
url="http://redis.io/"
#url="http://code.google.com/p/redis"
license=('BSD')
depends=('bash')
makedepends=('gcc>=3.1' 'make' 'pkgconfig')
backup=("etc/redis.conf"
"etc/logrotate.d/redis")
source=("http://redis.googlecode.com/files/${pkgname}-${pkgver}.tar.gz"
"redis.d"
"redis.logrotate")
md5sums=('ef273152151c3f905d284cbdbbdb234c'
'4f2c02b481283d1336508c988e60e8d8'
'9e2d75b7a9dc421122d673fe520ef17f')
build() {
cd "$srcdir/${pkgname}-${pkgver}"
CFLAGS="$CFLAGS -std=c99" make FORCE_LIBC_MALLOC=yes
}
package() {
cd "$srcdir/${pkgname}-${pkgver}"
mkdir -p $pkgdir/usr/bin
make INSTALL_BIN="$pkgdir/usr/bin" PREFIX=/usr install
install -D -m755 "$srcdir/${pkgname}-${pkgver}/COPYING" "$pkgdir/usr/share/licenses/redis/COPYING"
install -D -m755 "$srcdir/redis.d" "$pkgdir/etc/rc.d/redis"
install -Dm644 "$srcdir/redis.logrotate" "$pkgdir/etc/logrotate.d/redis"
sed -i 's|daemonize no|daemonize yes|;s|dir \./|dir /var/lib/redis/|;s|logfile stdout|logfile /var/log/redis.log| ' $srcdir/${pkgname}-${pkgver}/redis.conf
install -D -m644 "$srcdir/${pkgname}-${pkgver}/redis.conf" "$pkgdir/etc/redis.conf"
}
|
