blob: 34e8973f539d2af509c8edaafdc7d1cf0245b6ea (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# $Id: PKGBUILD 110190 2014-04-26 13:10:26Z lfleischer $
# Maintainer: Lukas Fleischer <archlinux at cryptocrack dot de>
# Contributor: Geoffrey Teale <tealeg@stop-squark>
# Contributor: Mark, Huo Mian <markhuomian[at]gmail[dot]com>
# Contributor: Biginoz <biginoz a free dot fr>
# Contributor: Mattias Andrée <`base64 -d`(bWFhbmRyZWUK)@member.fsf.org>
pkgname=redshift
pkgver=1.9.1
pkgrel=1
pkgdesc='Adjusts the color temperature of your screen according to your surroundings.'
arch=('i686' 'x86_64')
url='http://jonls.dk/redshift/'
license=('GPL3')
depends=('geoclue' 'libdrm' 'libxcb' 'libxxf86vm')
optdepends=('python-gobject: for redshift-gtk'
'python-xdg: for redshift-gtk'
'librsvg: for redshift-gtk')
makedepends=('python')
install='redshift.install'
source=("https://github.com/jonls/${pkgname}/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.xz")
md5sums=('4c5dd6ea043116f9c15a9d5ec4c608de')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr --enable-drm --enable-randr --enable-vidmode --enable-geoclue \
--with-systemduserunitdir=/usr/lib/systemd/user
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
}
|
