blob: 68fed6fab5e708113bf646b5780b7506ff8d4a11 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# $Id: PKGBUILD 92920 2013-06-19 10:05:52Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
pkgname=rsyslog
pkgver=7.4.1
pkgrel=1
pkgdesc="An enhanced multi-threaded syslogd with a focus on security and reliability"
url="http://www.rsyslog.com/"
arch=('i686' 'x86_64')
license=('GPL3')
depends=('zlib' 'libestr' 'libee' 'json-c' 'systemd')
makedepends=('postgresql-libs>=8.4.1' 'libmariadbclient' 'net-snmp' 'gnutls'
'python-docutils')
optdepends=('postgresql-libs: PostgreSQL Database Support'
'libmariadbclient: MySQL Database Support'
'net-snmp'
'gnutls')
backup=('etc/rsyslog.conf'
'etc/logrotate.d/rsyslog'
'etc/conf.d/rsyslog')
options=('strip' 'zipman' '!libtool')
source=("http://www.rsyslog.com/files/download/rsyslog/rsyslog-$pkgver.tar.gz"
'rsyslog.logrotate'
'rsyslog.conf')
md5sums=('8e0e868a425bfa5c2c13bdc28338e1af'
'0d990373f5c70ddee989296007b4df5b'
'd61dd424e660eb16401121eed20d98bc')
build() {
cd ${srcdir}/${pkgname}-${pkgver}
./configure --prefix=/usr \
--sbindir=/usr/bin \
--enable-mysql \
--enable-pgsql \
--enable-mail \
--enable-imfile \
--enable-snmp \
--enable-gnutls \
--enable-inet \
--enable-imjournal \
--enable-omjournal \
--with-systemdsystemunitdir=/usr/lib/systemd/system
echo "rsyslogd_LDADD += \$(LIBESTR_LIBS) -lm" >>tools/Makefile
make
}
package() {
cd ${srcdir}/${pkgname}-${pkgver}
make install DESTDIR=${pkgdir}
# Install Daemons and Configuration Files
install -D -m644 doc/${pkgname}-example.conf ${pkgdir}/usr/share/doc/$pkgname/${pkgname}.conf.example
install -D -m644 $srcdir/${pkgname}.conf ${pkgdir}/etc/${pkgname}.conf
install -D -m644 $srcdir/${pkgname}.logrotate ${pkgdir}/etc/logrotate.d/${pkgname}
# fix location of systemctl and remove start precondition
sed -i "$pkgdir/usr/lib/systemd/system/rsyslog.service" \
-e 's@/bin/systemctl@/usr&@' \
-e '/^ExecStartPre/d'
}
|
