blob: 92472a070be5d85603133a6da542d7f04f11ca9c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
# $Id: PKGBUILD 112658 2014-06-04 13:52:46Z bluewind $
# Maintainer: Sébastien Luttringer
# Contributor: Angel Velasquez <angvp@archlinux.org>
# Contributor: tobias <tobias@archlinux.org>
# Contributor: dibblethewrecker dibblethewrecker.at.jiwe.dot.org
pkgbase=rxvt-unicode
pkgname=('rxvt-unicode' 'rxvt-unicode-terminfo')
pkgver=9.20
pkgrel=2
arch=('i686' 'x86_64')
url='http://software.schmorp.de/pkg/rxvt-unicode.html'
license=('GPL')
makedepends=('libxft' 'perl' 'startup-notification')
source=(
"http://dist.schmorp.de/rxvt-unicode/$pkgname-$pkgver.tar.bz2"
'urxvt.desktop'
'urxvtc.desktop'
'urxvt-tabbed.desktop'
)
md5sums=('4a5b823f08d21036f94a6c51e94d025b'
'fec94dc986fa37ec380079d81de3e0b2'
'fac55f0a8404c86dad3e702146762332'
'8a5599197568c63720e282b9722a7990')
build() {
cd $pkgname-$pkgver
# we disable smart-resize (FS#34807)
./configure \
--prefix=/usr \
--with-terminfo=/usr/share/terminfo \
--enable-256-color \
--enable-combining \
--enable-fading \
--enable-font-styles \
--enable-iso14755 \
--enable-keepscrolling \
--enable-lastlog \
--enable-mousewheel \
--enable-next-scroll \
--enable-perl \
--enable-pointer-blank \
--enable-rxvt-scroll \
--enable-selectionscrolling \
--enable-slipwheeling \
--disable-smart-resize \
--enable-startup-notification \
--enable-transparency \
--enable-unicode3 \
--enable-utmp \
--enable-wtmp \
--enable-xft \
--enable-xim \
--enable-xterm-scroll \
--disable-pixbuf \
--disable-frills
make
}
package_rxvt-unicode() {
pkgdesc='An unicode enabled rxvt-clone terminal emulator (urxvt)'
depends=('rxvt-unicode-terminfo' 'libxft' 'perl' 'startup-notification')
optdepends=('gtk2-perl: to use the urxvt-tabbed')
# install freedesktop menu
for _f in urxvt urxvtc urxvt-tabbed; do
install -Dm644 $_f.desktop "$pkgdir/usr/share/applications/$_f.desktop"
done
cd $pkgname-$pkgver
# workaround terminfo installation
export TERMINFO="$srcdir/terminfo"
install -d "$TERMINFO"
make DESTDIR="$pkgdir" install
# install the tabbing wrapper ( requires gtk2-perl! )
sed -i 's/\"rxvt\"/"urxvt"/' doc/rxvt-tabbed
install -Dm 755 doc/rxvt-tabbed "$pkgdir/usr/bin/urxvt-tabbed"
}
package_rxvt-unicode-terminfo() {
pkgdesc='Terminfo files for urxvt'
conflict=('rxvt-unicode<=9.18-6')
install -dm 755 "$pkgdir/usr/share/"
mv terminfo "$pkgdir/usr/share/"
}
# vim:set ts=2 sw=2 et:
|
