blob: 1fadb25e316a845441471e4505bd8978b81f37ea (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# $Id: PKGBUILD 108952 2014-04-08 00:11:52Z bisson $
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
# Contributor: Ronald van Haren <ronald.archlinux.org>
# Contributor: tobias <tobias@archlinux.org>
# Contributor: Ben <ben@benmazer.net>
pkgname=scribus
pkgver=1.4.3
pkgrel=3
pkgdesc='Desktop publishing software'
url='http://www.scribus.net/'
license=('GPL')
arch=('i686' 'x86_64')
makedepends=('cmake' 'boost' 'mesa')
optdepends=('tk: scripts based on tkinter')
depends=('qt4' 'cairo' 'lcms2' 'libcups' 'libxml2' 'hyphen'
'ghostscript' 'python2' 'podofo' 'boost-libs'
'desktop-file-utils' 'shared-mime-info')
source=("http://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.xz"
'CalendarWizard.patch')
sha1sums=('30c111762790e4407c13236bbb4b06f04e907f71'
'a92629a98bc960a6f7f946faf2d6f06e9d1e9452')
install=install
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -p2 -i ../CalendarWizard.patch
sed 's|Icon=scribus|Icon=/usr/share/scribus/icons/scribus.png|' -i scribus.desktop
sed \
-e 's|#!/usr/bin/python|#!/usr/bin/python2|' \
-e 's|#!/usr/bin/env python|#!/usr/bin/env python2|' \
-i scribus/plugins/scriptplugin/{samples,scripts}/*
install -d ../build
}
build() {
cd "${srcdir}/build"
cmake "../${pkgname}-${pkgver}" \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_SKIP_RPATH=ON \
-DLIB_SUFFIX=""
make
}
package() {
cd "${srcdir}/build"
make DESTDIR="${pkgdir}" install
install -Dm644 "../${pkgname}-${pkgver}/scribus.desktop" "${pkgdir}/usr/share/applications/scribus.desktop"
}
|