blob: 2fbb4de623070a04e1276677d22e71eafbe7a09b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# $Id: PKGBUILD 80730 2012-12-01 17:20:47Z kkeen $
# Maintainer: Kyle Keen <keenerd@gmail.com>
pkgname=seamonkey
pkgver=2.14.1
pkgrel=1
pkgdesc="SeaMonkey internet suite"
arch=('i686' 'x86_64')
license=('MPL')
depends=('alsa-lib' 'dbus-glib' 'desktop-file-utils' 'gtk2' 'hunspell' 'libevent' 'libnotify' 'libvpx' 'libxt' 'mime-types' 'mozilla-common' 'nss' 'sqlite' 'startup-notification')
makedepends=('unzip' 'zip' 'pkg-config' 'python2' 'yasm' 'wireless_tools' 'mesa' 'autoconf2.13' 'imake')
install=$pkgname.install
url="http://www.seamonkey-project.org/"
source=(ftp://releases.mozilla.org/pub/mozilla.org/$pkgname/releases/$pkgver/source/$pkgname-$pkgver.source.tar.bz2
mozconfig
seamonkey.desktop
seamonkey-2.0-lang.patch)
md5sums=('19463b718446552d04130d01d25d7330'
'dabc8f517fbff67b8599064bedd32606'
'6119a2254716752c9d08e366f8d4c048'
'25b6fe16ac24cd5c852213e5c1adb272')
build() {
cd comm-release
cp ../mozconfig .mozconfig
patch -Np1 -i ../seamonkey-2.0-lang.patch
export LDFLAGS="$LDFLAGS -Wl,-rpath,/usr/lib/seamonkey-$pkgver"
export MOZ_MAKE_FLAGS="$MAKEFLAGS"
unset MAKEFLAGS
# Don't exit with error when some libs are missing which we have in
# system.
sed '/^MOZ_PKG_FATAL_WARNINGS/s@= 1@= 0@' \
-i suite/installer/Makefile.in
make -j1 -f client.mk build
}
package() {
cd comm-release
make -j1 -f client.mk DESTDIR="$pkgdir" install
rm -rf "$pkgdir"/usr/lib/seamonkey-$pkgver/{dictionaries,hyphenation}
ln -s /usr/share/hunspell "$pkgdir/usr/lib/seamonkey-$pkgver/dictionaries"
ln -s /usr/share/hyphen "$pkgdir/usr/lib/seamonkey-$pkgver/hyphenation"
install -m755 -d "$pkgdir/usr/share/applications"
install -m755 -d "$pkgdir/usr/share/pixmaps"
install -m644 suite/branding/nightly/icons/gtk/seamonkey.png \
"$pkgdir/usr/share/pixmaps/"
install -m644 "$srcdir/seamonkey.desktop" "$pkgdir/usr/share/applications/"
rm -f "$pkgdir/usr/lib/pkgconfig/"seamonkey-ns{s,pr}.pc
rm -r "$pkgdir"/usr/{include,lib/seamonkey-devel-$pkgver,share/idl}
}
|
