blob: b50775e4fd30a0f12a2a7987d89bc4de04aa3447 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# $Id: PKGBUILD 115539 2014-07-12 02:28:30Z svenstaro $
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: Adrián Chaves Fernández, aka Gallaecio <adriyetichaves@gmail.com>
# Contributor: Shahar Weiss <sweiss4@gmx.net> (build() code from his TORCS' PKGBUILD)
pkgname=speed-dreams
pkgver=2.1.0
_pkgver=2.1.0-r5799
pkgrel=1
pkgdesc="A racing simulator with rich graphics and physics"
arch=('i686' 'x86_64')
url="http://speed-dreams.sourceforge.net/"
license=('GPL2')
depends=('sdl' 'freealut' 'freeglut' 'libpng' 'libxi' 'libxmu' 'libxrandr' 'plib>=1.8.3' 'libjpeg' 'zlib' 'enet' 'speed-dreams-data' 'libvorbis' 'glu')
makedepends=('cmake' 'tar' 'mesa')
noextract=("${pkgname}-src-base-${_pkgver}.tar.xz"
"${pkgname}-src-unmaintained-${_pkgver}.tar.xz"
"${pkgname}-src-wip-cars-and-tracks-${_pkgver}.tar.xz"
"${pkgname}-src-hq-cars-and-tracks-${_pkgver}.tar.xz"
"${pkgname}-src-more-hq-cars-and-tracks-${_pkgver}.tar.xz")
source=("http://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-src-base-${_pkgver}.tar.xz"
"http://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-src-unmaintained-${_pkgver}.tar.xz"
"http://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-src-wip-cars-and-tracks-${_pkgver}.tar.xz"
"http://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-src-hq-cars-and-tracks-${_pkgver}.tar.xz"
"http://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-src-more-hq-cars-and-tracks-${_pkgver}.tar.xz"
"${pkgname}.desktop")
md5sums=('4e45e6ebf35b5afe52be4c4d24e670a7'
'293ff3117d9b82d7a509bb935cdd4d4b'
'1f4f32f726ee27fce30bbcd91c611b7f'
'09efa3454b1b0812169b5714821279e8'
'71f4be0d2b5589c32deb9b3686e69128'
'634f8cb8f4f96686c8049c8a025e72d0')
prepare() {
# extract these manually as bsdtar can't handle these
tar xf "${pkgname}-src-base-${_pkgver}.tar.xz"
tar xf "${pkgname}-src-unmaintained-${_pkgver}.tar.xz"
tar xf "${pkgname}-src-wip-cars-and-tracks-${_pkgver}.tar.xz"
tar xf "${pkgname}-src-hq-cars-and-tracks-${_pkgver}.tar.xz"
tar xf "${pkgname}-src-more-hq-cars-and-tracks-${_pkgver}.tar.xz"
}
build() {
cmake . \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DSD_BINDIR=/usr/bin \
-DSD_DATADIR=/usr/share/speed-dreams-2 \
-DSD_LIBDIR=/usr/lib/speed-dreams-2 \
-DOPTION_OFFICIAL_ONLY=ON
make
}
package() {
make DESTDIR="${pkgdir}/" install
rm -r "${pkgdir}/usr/share"
install -Dm644 "data/data/icons/icon.png" "${pkgdir}/usr/share/pixmaps/speed-dreams.png"
install -Dm644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/speed-dreams.desktop"
mkdir -p "${pkgdir}/usr/share/doc/${pkgname}"
cp -r doc/* "${pkgdir}/usr/share/doc/${pkgname}/"
# Symlink for backwards compatibility
cd "${pkgdir}/usr/bin"
ln -s speed-dreams-2 speed-dreams
}
# vim:set ts=2 sw=2 et:
|
