blob: 6a79c3e0ecb66c5a449dcfaa9ae4a205077e71b0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# $Id: PKGBUILD 107290 2014-03-16 16:03:43Z lfleischer $
# Maintainer: Lukas Fleischer <archlinux at cryptocrack dot de>
# Contributor: Kaiting Chen <kaitocracy@gmail.com>
# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
# Contributor: Kevin Piche <kevin@archlinux.org>
pkgname=stunnel
pkgver=5.00
pkgrel=1
pkgdesc="A program that allows you to encrypt arbitrary TCP connections inside SSL"
arch=('i686' 'x86_64')
url="http://www.stunnel.org"
license=('GPL')
depends=('openssl')
install=$pkgname.install
source=("https://www.stunnel.org/downloads/$pkgname-$pkgver.tar.gz"{,.asc}
'Makefile.patch'
'stunnel.tmpfiles.conf')
md5sums=('4f00fd0faf99e3c9cf258a19dd83d14a'
'SKIP'
'579f198ecb90a42fcbfd8a4e48006264'
'2e065a39998e57727ee79887bbd1751e')
build() {
cd "$srcdir/$pkgname-$pkgver"
# don't create a certificate...
patch -p0 <"$srcdir/Makefile.patch"
./configure --prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--enable-ipv6 \
--disable-libwrap
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
install -Dm644 tools/stunnel.cnf "$pkgdir/etc/stunnel/stunnel-openssl.cnf-sample"
install -Dm644 tools/stunnel.service "$pkgdir/usr/lib/systemd/system/stunnel.service"
install -Dm644 "$srcdir/stunnel.tmpfiles.conf" "$pkgdir/usr/lib/tmpfiles.d/stunnel.conf"
sed -e "s:/usr/var/lib/stunnel/:/var/run/stunnel:g" \
-e "s:/usr/etc/stunnel/:/etc/stunnel/:g" \
-e "s:no\(body\|group\):stunnel:g" \
-i "$pkgdir/etc/stunnel/stunnel.conf-sample"
}
|
