blob: 7aab8e795d2b3ea88a63d3e16e9c3ef25abd9488 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# $Id: PKGBUILD 116071 2014-07-21 17:07:55Z anatolik $
# Maintainer: Anatol Pomozov <anatol.pomozov@gmail.com>
# Contributor: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Angel Velasquez <angvp@archlinux.org>
# Contributor: unexist <unexist@dorfelite.net>
# Contributor: Abakus <java5@arcor.de>
# Contributor: TDY <tdy@gmx.com>
# Contributor: Xilon <xilonmu@gmail.com>
pkgname=subtle
# check the mercurial hash at http://hg.subforge.org/subtle
_hg_revision=3243
_hg_hash=43d1d0478c46
pkgver=0.11.r$_hg_revision
pkgrel=3
pkgdesc='Grid-based manual tiling window manager'
arch=(x86_64 i686)
url='http://subtle.subforge.org/'
license=(GPL)
depends=(ruby libxrandr libxft libxpm libxinerama libxtst)
backup=(etc/xdg/subtle/subtle.rb)
install=subtle.install
source=(http://hg.subforge.org/subtle/archive/$_hg_hash.tar.bz2
do_not_relink_binaries_on_install.diff)
sha256sums=('d3e29561a78a0491e6357ce60c940a1b050e99d116bffb7881d97b6a6b893137'
'448dd3bcc8fd3807ab0f66c1d82edccbeb830502dfe758770e7f7a76ffce35a0')
prepare() {
cd subtle-$_hg_hash
# Use vendor_ruby instead of site_ruby
sed -e \
's/RbConfig::CONFIG\["sitelibdir"\]/RbConfig::CONFIG\["vendorlibdir"\]/' \
-i Rakefile
patch -p1 < "$srcdir"/do_not_relink_binaries_on_install.diff
}
build() {
cd subtle-$_hg_hash
rake build revision=$_hg_revision
}
package() {
cd subtle-$_hg_hash
# regenerate config with proper $pkgdir, revision and cppflags are not needed at this step
rake config destdir="$pkgdir"
rake install
install -D -m644 data/subtle.desktop "$pkgdir"/usr/share/xsessions/subtle.desktop
}
|
