blob: ce9b3541736b848cf142e3fd2dd14bda020de5f6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# $Id: PKGBUILD 98716 2013-10-17 11:38:17Z svenstaro $
# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: Daenyth <Daenyth+Arch [AT] gmail [DOT] com>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: rabyte <rabyte__gmail>
pkgname=supertuxkart
pkgver=0.8
pkgrel=4
pkgdesc='Kart racing game featuring Tux and his friends'
arch=('i686' 'x86_64')
url='http://supertuxkart.sourceforge.net/'
license=('GPL2')
depends=('openal' 'libvorbis' 'libgl' 'fribidi' 'curl')
makedepends=('cmake' 'subversion' 'mesa' 'imagemagick' 'setconf')
source=("http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver-src.tar.bz2")
install=supertuxkart.install
md5sums=('0b939ce601374758938119e0b0dd1fec')
build() {
cd ${srcdir}/SuperTuxKart-${pkgver}
_fn="data/${pkgname}_desktop.template"
setconf "$_fn" Exec "$pkgname --log=file"
setconf "$_fn" TryExec "$pkgname"
setconf "$_fn" Icon "$pkgname"_64
cd lib/irrlicht/source/Irrlicht
NDEBUG=1 make
cd ${srcdir}/SuperTuxKart-${pkgver}
#sed -i "s|share/games|share|g" CMakeLists.txt
[[ -d build ]] && rm -r build
mkdir build && cd build
cmake \
-DIRRLICHT_DIR="$srcdir/irrlicht" \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_CXX_FLAGS="-lpthread -lm -ldl" \
..
make
}
package() {
cd ${srcdir}/SuperTuxKart-${pkgver}
cd build
make DESTDIR=${pkgdir} install
}
# vim:set ts=2 sw=2 et:
|
