blob: 70d7a4ca4ab0ac8714e62e4060d423a89aabcf3c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# $Id: PKGBUILD 60193 2011-12-07 12:16:33Z arodseth $
# Maintainer: Alexander Rødseth
# Contributor: Stefan Husmann <stefan-husmann@t-online.de>
# Contributor: TripleE <eric1548@yahoo.com>
pkgname=sword
pkgver=1.6.2
pkgrel=6
pkgdesc="Libraries for Bible programs"
arch=('x86_64' 'i686')
url="http://www.crosswire.org/sword/"
license=('GPL')
depends=('curl' 'clucene' 'swig')
makedepends=('cmake')
backup=('etc/sword.conf')
source=("http://www.crosswire.org/ftpmirror/pub/$pkgname/source/v1.6/$pkgname-$pkgver.tar.gz"
curl.patch)
md5sums=('a7dc4456e20e915fec46d774b690e305'
'e84a226ce3697af33b9fdd9a22884a2a')
build() {
cd "$srcdir/$pkgname-$pkgver"
patch -p1 -i ../curl.patch
mkdir ../build
cd ../build
cmake "../$pkgname-$pkgver" \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_BUILD_TYPE=Release
make
}
package() {
cd "$srcdir/build"
make DESTDIR="$pkgdir" install
install -d "$pkgdir/usr/lib/sword"
mv "$pkgdir"/usr/lib/1.6.2_icu_4.8* "$pkgdir/usr/lib/sword/"
cd "$srcdir/$pkgname-$pkgver/locales.d/"
for file in *.conf; do
install -Dm644 "$file" "$pkgdir/usr/share/sword/locales.d/$file"
done
cd ../include
install -d "$pkgdir/usr/include/sword"
install -Dm644 canon_{catholic{,2},synodalp}.h "$pkgdir/usr/include/sword"
cd ../samples
install -Dm644 mods.d/globals.conf "$pkgdir/usr/share/sword/mods.d/globals.conf"
install -Dm644 recommended/sword.conf "$pkgdir/etc/sword.conf"
}
# vim:set ts=2 sw=2 et:
|
