blob: ef059484d2dce60a5c56c0618ce62684ef29b89e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# $Id: PKGBUILD 97561 2013-09-24 10:31:09Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Uroš Vampl <mobile.leecher at gmail dot com>
pkgname=tigervnc
pkgver=1.3.0
pkgrel=3
_xorgver=1.14.2
pkgdesc="suite of VNC servers and clients. VNC 4 branch of TightVNC."
arch=('i686' 'x86_64')
url="http://www.tigervnc.org"
license=('GPL')
depends=('fltk' 'pam' 'gnutls' 'libjpeg-turbo' 'libxtst' 'libxfont' 'pixman'
'xorg-xauth' 'xorg-xsetroot' 'xkeyboard-config' 'xorg-xkbcomp'
'libgl' 'libgcrypt' 'perl' )
makedepends=('cmake' 'nasm' 'xorg-font-util' 'xorg-util-macros' 'bigreqsproto'
'compositeproto' 'damageproto' 'randrproto' 'resourceproto'
'scrnsaverproto' 'videoproto' 'xcmiscproto' 'xf86vidmodeproto'
'xtrans' 'mesa' 'glproto' 'dri2proto' 'imagemagick')
options=(!libtool)
conflicts=('tightvnc')
source=(http://downloads.sourceforge.net/project/tigervnc/tigervnc/$pkgver/tigervnc-$pkgver.tar.bz2
ftp://ftp.freedesktop.org/pub/xorg/individual/xserver/xorg-server-${_xorgver}.tar.bz2
vncserver.service
vncviewer.desktop
gethomedir.patch
getmaster.patch)
md5sums=('a5158228e64d14496821a39bf3851f1b'
'5d36a6483e8e301875131e8302c67727'
'0903d5a0dfa38e0b04964505b644585c'
'71cac0fb9701b0a041430f0fddfe00c8'
'22f1523a0eca56ad79cfabd0db6e2cf6'
'e056a2502dfe0cb3b02e08cab689482f')
prepare() {
cd ${srcdir}/${pkgname}-${pkgver}
cp -r ${srcdir}/xorg-server-${_xorgver}/* unix/xserver
patch -Np1 -i ${srcdir}/gethomedir.patch
patch -Np1 -i ${srcdir}/getmaster.patch
}
build() {
cd ${srcdir}/${pkgname}-${pkgver}
cmake -G "Unix Makefiles" -DCMAKE_INSTALL_PREFIX=/usr
make
cd unix/xserver
patch -Np1 -i ../xserver114.patch
autoreconf -fiv
./configure --prefix=/usr \
--disable-static --disable-xinerama --without-dtrace \
--disable-xorg --disable-xnest --disable-xvfb --disable-dmx \
--disable-xwin --disable-xephyr --disable-kdrive --with-pic \
--disable-config-dbus --disable-config-hal --disable-config-udev \
--disable-unit-tests --disable-devel-docs --disable-selective-werror \
--disable-dri --enable-dri2 --enable-glx --enable-glx-tls
make
}
package() {
cd ${srcdir}/${pkgname}-${pkgver}
make DESTDIR=${pkgdir} install
cd unix/xserver/hw/vnc
make DESTDIR=${pkgdir} install
sed -i 's/iconic/nowin/' ${pkgdir}/usr/bin/vncserver
install -Dm0644 $srcdir/vncserver.service $pkgdir/usr/lib/systemd/system/vncserver.service
install -Dm0644 $srcdir/vncviewer.desktop $pkgdir/usr/share/applications/vncviewer.desktop
}
|
