blob: cc82955553a8dccb30ea6f65a620c65f50c318fb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# $Id: PKGBUILD 95204 2013-08-06 14:56:23Z tpowa $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Maintainer: Sébastien Luttringer
pkgbase=virtualbox-modules
pkgname=('virtualbox-host-modules' 'virtualbox-guest-modules')
pkgver=4.2.16
pkgrel=5
arch=('i686' 'x86_64')
url='http://virtualbox.org'
license=('GPL')
makedepends=('linux>=3.10' 'linux<3.11'
'linux-headers>=3.10' 'linux-headers<3.11'
"virtualbox-host-dkms>=$pkgver"
"virtualbox-guest-dkms>=$pkgver"
'expac'
'sed'
'bc')
# remember to also adjust the .install files and the package deps below
_extramodules=extramodules-3.10-ARCH
build() {
_kernver="$(cat /usr/lib/modules/$_extramodules/version)"
# dkms need modification to be run as user
cp -r /var/lib/dkms .
echo "dkms_tree='$srcdir/dkms'" > dkms.conf
# build host modules
msg2 'Host modules'
dkms --dkmsframework dkms.conf build "vboxhost/$pkgver" -k "$_kernver"
# build guest modules
msg2 'Guest modules'
dkms --dkmsframework dkms.conf build "vboxguest/$pkgver" -k "$_kernver"
}
package_virtualbox-host-modules(){
_kernver="$(cat /usr/lib/modules/$_extramodules/version)"
pkgdesc='Host kernel modules for VirtualBox'
depends=('linux>=3.10' 'linux<3.11')
replaces=('virtualbox-modules')
conflicts=('virtualbox-modules')
install=virtualbox-host-modules.install
cd "dkms/vboxhost/$pkgver/$_kernver/$CARCH/module"
install -dm755 "$pkgdir/usr/lib/modules/$_extramodules/"
install -m644 * "$pkgdir/usr/lib/modules/$_extramodules/"
find "$pkgdir" -name '*.ko' -exec gzip -9 {} +
}
package_virtualbox-guest-modules(){
_kernver="$(cat /usr/lib/modules/$_extramodules/version)"
pkgdesc='Guest kernel modules for VirtualBox'
license=('GPL')
depends=('linux>=3.10' 'linux<3.11')
replaces=('virtualbox-archlinux-modules')
conflicts=('virtualbox-archlinux-modules')
install=virtualbox-guest-modules.install
cd "dkms/vboxguest/$pkgver/$_kernver/$CARCH/module"
install -dm755 "$pkgdir/usr/lib/modules/$_extramodules/"
install -m644 * "$pkgdir/usr/lib/modules/$_extramodules/"
find "$pkgdir" -name '*.ko' -exec gzip -9 {} +
}
# vim:set ts=2 sw=2 et:
|
