blob: f96430d3c18c1aeb904806d778e2b87f4b85b3f6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# $Id: PKGBUILD 94932 2013-08-01 07:01:29Z bpiotrowski $
# Maintainer: Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor: juergen <juergen@archlinux.org>
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>
pkgname=xemacs
pkgver=21.5.33
pkgrel=3
pkgdesc="An highly customizable open source text editor and application development system forked from GNU Emacs"
arch=('i686' 'x86_64')
url="http://www.xemacs.org/"
license=('GPL')
depends=('db' 'libpng' 'libtiff' 'gpm' 'desktop-file-utils' 'libxaw' 'gdbm' 'giflib')
optdepends=('xorg-fonts-75dpi: X bitmap fonts needed for the interface'
'xorg-fonts-100dpi: X bitmap fonts needed for the interface')
makedepends=('xbitmaps')
install=$pkgname.install
source=(http://ftp.xemacs.org/pub/xemacs/beta/${pkgname}-${pkgver}.tar.gz
xemacs.desktop)
sha256sums=('448c76aa32cd5c84257027846f01b75a5e4f1e9db3278f95e68ff23d59fb8f94'
'd6dc802cf07519584aa28f3b5f4ae84d5e18b619ddd7e89a04da2f6783125f34')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --build="${CHOST}" --prefix=/usr --with-dynamic \
--without-postgresql --with-athena=xaw \
--enable-database=berkdb --without-ldap \
--enable-menubars=lucid --enable-scrollbars=lucid \
--enable-widgets=athena --enable-dialogs=athena \
--enable-external-widget \
--with-jpeg --with-png --with-tiff \
--with-ncurses --with-pop --with-xfs --disable-sound \
--infodir=/usr/share/info \
--with-mule \
--mandir=/usr/share/man/man1
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make -j1 prefix="${pkgdir}/usr" mandir="${pkgdir}/usr/share/man/man1" infodir="${pkgdir}/usr/share/info" install gzip-el
rm "${pkgdir}"/usr/bin/{b2m,ctags,etags}
rm "${pkgdir}"/usr/share/man/man1/{ctags.1,etags.1}
# fix FS#7927
install -d -m755 "${pkgdir}/usr/share/pixmaps"
install -D -m644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
ln -sf /usr/share/xemacs-${pkgver%.*}-b${pkgver##*.}/etc/xemacs-icon.xpm "${pkgdir}/usr/share/pixmaps/xemacs-icon.xpm"
# correct permissions
chown -R root:root "${pkgdir}"
rm "${pkgdir}"/usr/share/info/{info.info,texinfo.info-2,cl.info,texinfo.info-1,texinfo.info,standards.info,widget.info}
}
|
