blob: 054146c43407c9e071c1d4adbb719f6d5d6a9df9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# $Id: PKGBUILD 74151 2012-07-22 12:17:46Z arodseth $
# Maintainer: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Daenyth <Daenyth+Arch [at] gmail [dot] com>
# Contributor: Pierre Schmitz <pierre@archlinux.de>
# Contributor: Vitaliy Berdinskikh <skipper13@root.ua>
pkgname=xmlrpc-c
pkgver=1.31.02
epoch=1
pkgrel=2
pkgdesc='XML-RPC for C and C++'
arch=('x86_64' 'i686')
url='http://xmlrpc-c.sourceforge.net/'
license=('custom')
depends=('curl' 'libxml2' 'gcc-libs' 'zlib')
makedepends=('libtool' 'setconf')
options=('!makeflags' '!libtool')
source=("$pkgname-advanced-$pkgver.tar.gz::http://xmlrpc-c.svn.sourceforge.net/viewvc/xmlrpc-c/advanced.tar.gz")
sha256sums=('8310eb35268150724daf8eecb8fb3a3421a01da8d30ed3e9cdd66cbc7ad93874')
build() {
cd "$srcdir/advanced"
[ "$CARCH" != "i686" ] && export CFLAGS="$CFLAGS -fPIC"
./configure --prefix=/usr \
--mandir=/usr/share/man \
--enable-libxml2-backend \
--disable-cgi-server \
--disable-abyss-server \
--disable-libwww-client \
--disable-wininet-client
mkdir include/curl
touch include/curl/types.h
make CFLAGS_PERSONAL="$CFLAGS"
}
package() {
cd "$srcdir/advanced"
make DESTDIR="$pkgdir" install
install -Dm644 doc/COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
# Remove references to build directory
setconf "$pkgdir/usr/bin/xmlrpc-c-config" BLDDIR ""
setconf "$pkgdir/usr/bin/xmlrpc-c-config" ABS_SRCDIR ""
}
# vim:set ts=2 sw=2 et:
|
