blob: 80ac28e5ee5ed1b6a0092e722ae410bcba2e750a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id: PKGBUILD 94626 2013-07-29 00:15:08Z speps $
# Maintainer : speps <speps at aur dot archlinux dot org>
# Contributor: Philipp Überbacher <murks at lavabit dot com>
# Contributor: Stefan Husmann <stefan-husmann@t-online.de>
# Contributor: orbisvicis
pkgname=zita-convolver
pkgver=3.1.0
pkgrel=2
pkgdesc="A fast, partitioned convolution engine library."
arch=('i686' 'x86_64')
url="http://kokkinizita.linuxaudio.org/linuxaudio/"
license=('GPL3')
depends=('gcc-libs' 'fftw')
source=("${url}downloads/zita-convolver-$pkgver.tar.bz2")
md5sums=('7e264d0fb0d8ea277cdb4e33d764c68a')
prepare() {
cd "$srcdir/$pkgname-$pkgver/libs"
# FS#36248 - strip -march=native
sed -i '/native/d' Makefile
# prevent ldconfig call
sed -i '/ldconfig/d' Makefile
}
build() {
cd "$srcdir/$pkgname-$pkgver/libs"
make
}
package() {
cd "$srcdir/$pkgname-$pkgver/libs"
make SUFFIX="" PREFIX=/usr DESTDIR="$pkgdir/" install
# missing softlink
ln -s lib$pkgname.so.$pkgver \
"$pkgdir/usr/lib/lib$pkgname.so.${pkgver%%.*}"
}
|
