blob: 1fb3cfd039ea3214956c6edf6435e286d4d8df63 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# $Id: PKGBUILD 215348 2014-06-23 07:30:53Z ronald $
# Maintainer: Ronald van Haren <ronald.archlinux.org>
# Contributor: Tom Killian <tom.archlinux.org>
# Contributor: Judd Vinet <jvinet.zeroflux.org>
pkgname=dhcpcd
pkgver=6.4.0
pkgrel=1
pkgdesc="RFC2131 compliant DHCP client daemon"
url="http://roy.marples.name/projects/dhcpcd/"
arch=('i686' 'x86_64')
license=('BSD')
groups=('base')
depends=('glibc' 'sh')
provides=('dhcp-client')
backup=('etc/dhcpcd.conf')
options=('emptydirs') # We Need the Empty /var/lib/dhcpcd Directory
source=("http://roy.marples.name/downloads/$pkgname/$pkgname-$pkgver.tar.bz2"
'dhcpcd_.service'
'dhcpcd.service')
sha1sums=('77eb7b909cc9b1f9f178f1ba7b79dbb8fe5389ef'
'6f1633edde14d29b5cdc09c4f029a450ef2ebc96'
'52c1bad9ab43e9a253c1eb175e7eefb13497b8f9')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
# configure variables
./configure \
--sbindir=/usr/bin \
--libexecdir=/usr/lib/dhcpcd \
--dbdir=/var/lib/dhcpcd \
--rundir=/run
# Build
make
}
check() {
cd "${srcdir}/${pkgname}-${pkgver}"
make test
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
# Install License
install -d "$pkgdir/usr/share/licenses/$pkgname"
sed 26q "$srcdir/$pkgname-$pkgver/control.h" \
>>"$pkgdir/usr/share/licenses/$pkgname/LICENSE"
# Set Options in /etc/dhcpcd.conf
echo noipv4ll >> "${pkgdir}/etc/dhcpcd.conf" # Disable ip4vall
# install systemd files
install -Dm644 "${srcdir}/dhcpcd_.service" "${pkgdir}/usr/lib/systemd/system/dhcpcd@.service"
install -Dm644 "${srcdir}/dhcpcd.service" "${pkgdir}/usr/lib/systemd/system/dhcpcd.service" # FS#31543
}
|
