blob: c3962c2f8880c4869a9d50274c097f30eedbff66 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# $Id: PKGBUILD 102182 2010-12-06 14:43:36Z allan $
# Maintainer: Allan McRae <allan@archlinux.org>
# Contributor: Jochem Kossen <j.kossen@home.nl>
pkgname=fakeroot
pkgver=1.14.5
pkgrel=1
pkgdesc="Gives a fake root environment, useful for building packages as a non-privileged user"
arch=('i686' 'x86_64')
license=('GPL')
url="http://packages.debian.org/fakeroot"
groups=('base-devel')
install=fakeroot.install
depends=('glibc' 'filesystem' 'grep' 'sed' 'sh')
options=('!libtool')
source=(http://ftp.debian.org/debian/pool/main/f/${pkgname}/${pkgname}_${pkgver}.orig.tar.bz2)
md5sums=('659a1f3a36554abfc2a3eaad2fdc0604')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr --libdir=/usr/lib/libfakeroot \
--disable-static --with-ipc=sysv
# --with-ipc=tcp is currently broken and no option on smp systems
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR=${pkgdir} install
install -dm755 ${pkgdir}/etc/ld.so.conf.d/
echo '/usr/lib/libfakeroot' > ${pkgdir}/etc/ld.so.conf.d/fakeroot.conf
# install README for sysv/tcp usage
install -Dm644 $srcdir/$pkgname-$pkgver/README $pkgdir/usr/share/doc/$pkgname/README
}
|
