blob: db0e5dd2e884ef37eb419a1b0e3c10fc4da0b6b4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# $Id: PKGBUILD 178149 2013-02-17 00:23:25Z bisson $
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Tobias Powalowski <tpowa@archlinux.org>
# Contributor: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Judd Vinet <jvinet@zeroflux.org>
pkgname=gnupg
pkgver=2.0.19
pkgrel=6
pkgdesc='Complete and free implementation of the OpenPGP standard'
url='http://www.gnupg.org/'
license=('GPL')
arch=('i686' 'x86_64')
optdepends=('curl: gpg2keys_curl'
'libldap: gpg2keys_ldap'
'libusb-compat: scdaemon')
makedepends=('curl' 'libldap' 'libusb-compat')
depends=('bzip2' 'libksba' 'libgcrypt' 'pth' 'libassuan' 'readline' 'pinentry' 'dirmngr')
source=("ftp://ftp.gnupg.org/gcrypt/${pkgname}/${pkgname}-${pkgver}.tar.bz2"{,.sig}
'valid-keyblock-packet.patch'
'protect-tool-env.patch')
sha1sums=('190c09e6688f688fb0a5cf884d01e240d957ac1f'
'f6e6830610a8629b0aad69d789373bf8ca481733'
'474d827f1c2976bb107985047f61ac9096ae0953'
'2ec97ba55ae47ff0d63bc813b8c64cb79cef11db')
install=install
conflicts=('gnupg2')
provides=("gnupg2=${pkgver}")
replaces=('gnupg2')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -p1 -i ../protect-tool-env.patch # FS#31900
patch -p1 -i ../valid-keyblock-packet.patch
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/lib/gnupg \
--enable-maintainer-mode \
--enable-symcryptrun \
--enable-gpgtar \
make
}
check() {
cd "${srcdir}/${pkgname}-${pkgver}"
make check
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
ln -s gpg2 "${pkgdir}"/usr/bin/gpg
ln -s gpgv2 "${pkgdir}"/usr/bin/gpgv
ln -s gpg2.1.gz "${pkgdir}"/usr/share/man/man1/gpg.1.gz
rm "${pkgdir}/usr/share/gnupg/com-certs.pem" # FS#33059
}
|
