blob: efc4eda5c1d933761a566f78573a27192b3ce3b0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# $Id: PKGBUILD 162361 2012-06-25 20:10:09Z stephane $
# Maintainer: Stéphane Gaudreault <stephane@archlinux.org>
# Maintainer: Tobias Powalowski <tpowa@archlinux.org>
# Contributor: Aaron Griffin <aaron@archlinux.org>
pkgname=iputils
pkgver=20101006
pkgrel=3
pkgdesc="IP Configuration Utilities (and Ping)"
arch=('i686' 'x86_64')
license=('GPL')
url="http://www.linuxfoundation.org/en/Net:Iputils"
groups=('base')
depends=('openssl' 'sysfsutils' 'libcap')
optdepends=('xinetd: for tftpd')
makedepends=('docbook2x' 'opensp')
conflicts=('netkit-base' 'arping' 'netkit-tftpd')
replaces=('netkit-base')
backup=(etc/xinetd.d/tftp)
install=${pkgname}.install
source=(http://www.skbuff.net/${pkgname}/${pkgname}-s${pkgver}.tar.bz2 tftp.xinetd)
sha1sums=('a08cc5423a7bf940205f2353fe3d129cd39ff242'
'fc2ae26f5609725e3f4aeaf4ab82dfa6d2e378fd')
build() {
cd "${srcdir}/${pkgname}-s${pkgver}"
# Use our CFLAGS
sed -i -e "/^CCOPT=/s|-O2|${CFLAGS}|" Makefile
make
cd doc
for file in *.sgml; do
xf=${file/.sgml/.xml}
osx -xlower -xno-nl-in-tag $file > $xf || true
sed -i "s|<refname>\(.*\), \(.*\)</refname>|<refname>\1</refname>, <refname>\2</refname>|g" $xf
docbook2man $xf
done
}
package() {
cd "${srcdir}/${pkgname}-s${pkgver}"
install -dm755 "${pkgdir}"/usr/{bin,sbin} "${pkgdir}"/bin
install -m755 arping clockdiff rarpd rdisc tftpd tracepath tracepath6 \
"${pkgdir}"/usr/sbin/
install -m755 ping{,6} "${pkgdir}"/usr/bin/
ln -sf /usr/bin/ping{,6} "${pkgdir}"/bin/
install -dm755 "${pkgdir}"/usr/share/man/man8
install -m644 doc/{arping,clockdiff,ping,rarpd,rdisc,tftpd,tracepath}.8 \
"${pkgdir}"/usr/share/man/man8/
cd "${pkgdir}"/usr/share/man/man8
ln -sf ping.8.gz ping6.8.gz
ln -sf tracepath.8.gz tracepath6.8.gz
# FS#24768
install -dm755 "${pkgdir}"/etc/xinetd.d/
install -m644 "${srcdir}"/tftp.xinetd "${pkgdir}"/etc/xinetd.d/tftp
}
# vim:set ts=2 sw=2 et:
|
