blob: 1193ed3b02827006e06d2a4a4722082e97f8fc0d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# $Id: PKGBUILD 148998 2012-02-05 12:58:31Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>
pkgname=links
pkgver=2.5
pkgrel=1
pkgdesc="A text WWW browser, similar to Lynx"
arch=('i686' 'x86_64')
url="http://links.twibright.com/"
license=('GPL')
depends=('bzip2' 'xz' 'zlib' 'openssl' 'gpm')
makedepends=('libtiff' 'libpng' 'libxt')
optdepends=('libx11: for using xlinks' 'libtiff: for using xlinks' 'libpng: for using xlinks')
provides=('links-g')
conflicts=('links-g')
replaces=('links-g')
source=(http://links.twibright.com/download/${pkgname}-${pkgver}.tar.bz2 links.desktop)
sha1sums=('fe4bc37be8aebd9196c35ffef724435cea94349c'
'f600e27c2a71184444f7dd07a10230aa44463a02')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
(cd intl; ./gen-intl; ./synclang)
./configure --prefix=/usr --mandir=/usr/share/man --enable-javascript \
--enable-graphics --with-x --with-fb
make
mv links xlinks
./configure --prefix=/usr --mandir=/usr/share/man --enable-javascript \
--disable-graphics --without-x --without-fb
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -m755 xlinks "${pkgdir}/usr/bin/xlinks"
ln -s links.1.gz "${pkgdir}/usr/share/man/man1/xlinks.1.gz"
install -D -m644 "${srcdir}/links.desktop" "${pkgdir}/usr/share/applications/links.desktop"
install -d "${pkgdir}/usr/share/pixmaps"
install -m644 links_16x16_1.xpm links_16x16_2.xpm links_32x32.xpm "${pkgdir}/usr/share/pixmaps/"
install -d "${pkgdir}/usr/share/doc/links/calibration"
install -m644 doc/links_cal/* "${pkgdir}/usr/share/doc/links/calibration/"
}
|
