core/module-init-tools/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# $Id: PKGBUILD 105077 2011-01-06 02:59:10Z allan $
# Maintainer: Aaron Griffin <aaron@archlinux.org>
# Contributor: judd <jvinet@zeroflux.org>

pkgname=module-init-tools
pkgver=3.12
pkgrel=2
pkgdesc="utilities needed by Linux systems for managing loadable kernel modules"
arch=('i686' 'x86_64')
url="http://kerneltools.org"
license=('GPL')
depends=('glibc')
backup=('etc/modprobe.d/modprobe.conf')
source=(http://www.kernel.org/pub/linux/utils/kernel/module-init-tools/module-init-tools-$pkgver.tar.bz2
        modprobe.conf)
md5sums=('8b2257ce9abef74c4a44d825d23140f3'
         '316f1bda4c21af02b30252eb014a0a55')

build() {
  cd $srcdir/$pkgname-$pkgver
  
  # do not regenerate man pages
  touch *.{5,8}
  
  ./configure --prefix=/usr --exec-prefix=/ --enable-zlib
  make
}

package() {
  cd $srcdir/$pkgname-$pkgver

  make DESTDIR=$pkgdir install
 
  # Install our custom (read: empty) modprobe.conf
  install -Dm644 $srcdir/modprobe.conf $pkgdir/etc/modprobe.d/modprobe.conf
  
  # fix man page (FS#17559)
  sed -i "s#mod#man5/mod#" $pkgdir/usr/share/man/man5/modprobe.d.5
}