blob: 4696adad5a49524921c73de3f1539d96ccc81189 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# $Id: PKGBUILD 210195 2014-04-11 09:28:05Z thomas $
# Maintainer: Thomas Bächler <thomas@archlinux.org>
pkgname=openvpn
pkgver=2.3.3
pkgrel=1
pkgdesc="An easy-to-use, robust, and highly configurable VPN (Virtual Private Network)"
arch=(i686 x86_64)
url="http://openvpn.net/index.php/open-source.html"
depends=('openssl' 'lzo2' 'iproute2')
makedepends=('systemd')
license=('custom')
install=openvpn.install
source=(http://swupdate.openvpn.net/community/releases/openvpn-${pkgver}.tar.gz
http://swupdate.openvpn.net/community/releases/openvpn-${pkgver}.tar.gz.asc
openvpn@.service)
md5sums=('5c66ea3143ac884a3075521bd74ede06'
'SKIP'
'71fab8d1c2aa3a1f2609e259eaaf88b3')
build() {
cd "${srcdir}"/$pkgname-$pkgver
CFLAGS="$CFLAGS -DPLUGIN_LIBDIR=\\\"/usr/lib/openvpn\\\"" ./configure \
--prefix=/usr \
--sbindir=/usr/bin \
--enable-password-save \
--mandir=/usr/share/man \
--enable-iproute2 \
--enable-systemd
make
}
package() {
cd "${srcdir}"/$pkgname-$pkgver
# Install openvpn
make DESTDIR="${pkgdir}" install
install -d -m755 "${pkgdir}"/etc/openvpn
# Install examples
install -d -m755 "${pkgdir}"/usr/share/openvpn
cp -r sample/sample-config-files "${pkgdir}"/usr/share/openvpn/examples
# Install license
install -d -m755 "${pkgdir}"/usr/share/licenses/${pkgname}/
ln -sf /usr/share/doc/${pkgname}/{COPYING,COPYRIGHT.GPL} "${pkgdir}"/usr/share/licenses/${pkgname}/
# Install contrib
install -d -m755 "${pkgdir}"/usr/share/openvpn/contrib
cp -r contrib "${pkgdir}"/usr/share/openvpn
# Install systemd service
install -D -m644 "${srcdir}"/openvpn@.service "${pkgdir}"/usr/lib/systemd/system/openvpn@.service
}
|
