blob: f2f551bc56ac68306855eace01025916f988d74f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# $Id: PKGBUILD 214744 2014-06-09 08:32:36Z bisson $
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>
# Contributor: Sergej Pupykin <pupykin.s@arch@gmail.com>
# Contributor: Andreas Wagner <Andreas.Wagner@em.uni-frankfurt.de>
pkgname=s-nail
pkgver=14.7
pkgrel=1
pkgdesc='Mail processing system with a command syntax reminiscent of ed'
url='http://sdaoden.users.sourceforge.net/code.html#s-nail'
license=('custom:BSD')
arch=('i686' 'x86_64')
depends=('openssl')
optdepends=('smtp-forwarder: for sending mail')
source=("http://downloads.sourceforge.net/project/${pkgname}/${pkgname}-${pkgver//./_}.tar.xz")
sha1sums=('9eb367d017cdcb6eccc0f8d0064ac4565518c248')
groups=('base')
backup=('etc/mail.rc')
replaces=('mailx' 'mailx-heirloom' 'heirloom-mailx')
provides=('mailx' 'mailx-heirloom' 'heirloom-mailx')
conflicts=('mailx' 'mailx-heirloom' 'heirloom-mailx')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
make \
PREFIX=/usr \
SYSCONFDIR=/etc \
MANDIR=/usr/share/man \
MAILSPOOL=/var/spool/mail \
SID= NAIL=mail \
config
make build
}
check() {
cd "${srcdir}/${pkgname}-${pkgver}"
make test
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" packager-install
ln -sf mail "${pkgdir}"/usr/bin/mailx
ln -sf mail.1.gz "${pkgdir}"/usr/share/man/man1/mailx.1.gz
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}
|
