blob: c9ae178027e49308c203f45de94d3f50883e8995 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# $Id: PKGBUILD 180116 2013-03-17 15:39:56Z foutrelis $
# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>
pkgname=sudo
_sudover=1.8.6p7
pkgver=${_sudover/p/.p}
pkgrel=2
pkgdesc="Give certain users the ability to run some commands as root"
arch=('i686' 'x86_64')
url="http://www.sudo.ws/sudo/"
license=('custom')
groups=('base-devel')
depends=('glibc' 'pam')
backup=('etc/sudoers' 'etc/pam.d/sudo')
options=('!libtool')
source=(http://www.sudo.ws/sudo/dist/$pkgname-$_sudover.tar.gz{,.sig}
sudo.pam)
sha256sums=('301089edb22356f59d097f6abbe1303f03927a38691b02959d618546c2125036'
'ab7660cbaba45f6aff03abbae69a62e9644a86bed76b53334364147569f104d6'
'e7de79d2c73f2b32b20a8e797e54777a2bf19788ec03e48decd6c15cd93718ae')
build() {
cd "$srcdir/$pkgname-$_sudover"
./configure \
--prefix=/usr \
--libexecdir=/usr/lib \
--with-logfac=auth \
--with-pam \
--with-env-editor \
--with-passprompt="[sudo] password for %p: " \
--with-all-insults
make
}
check() {
cd "$srcdir/$pkgname-$_sudover"
make check
}
package() {
cd "$srcdir/$pkgname-$_sudover"
make DESTDIR="$pkgdir" install
install -Dm644 "$srcdir/sudo.pam" "$pkgdir/etc/pam.d/sudo"
install -Dm644 doc/LICENSE "$pkgdir/usr/share/licenses/sudo/LICENSE"
}
# vim:set ts=2 sw=2 et:
|
