blob: fdc3ecb23fae212d0ea2eabd67c77497c8974072 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# $Id: PKGBUILD 156699 2012-04-23 09:03:23Z ibiru $
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Harley Laue <losinggeneration@yahoo.com>
pkgname=anjuta
pkgver=3.4.0
pkgrel=3
pkgdesc="GNOME Integrated Development Environment (IDE)"
arch=('i686' 'x86_64')
license=('GPL')
depends=('vte3' 'gdl' 'autogen' 'devhelp' 'glade' 'libgda' 'subversion' 'gnome-icon-theme' 'vala' 'dconf')
makedepends=('gnome-doc-utils' 'intltool' 'gobject-introspection')
url="http://anjuta.sourceforge.net/"
install=anjuta.install
source=(ftp://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz)
options=('!libtool' '!emptydirs')
sha256sums=('c8175e04e797dc0e2aaede4ae73ee9cd7f37d3e59b158961703db546d4660abf')
build() {
cd "$srcdir/$pkgname-$pkgver"
PYTHON=/usr/bin/python2 ./configure --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --disable-scrollkeeper
make
}
package(){
cd "$srcdir/$pkgname-$pkgver"
# j1: Race during linking
make -j1 DESTDIR="$pkgdir" install
sed -i "1s|#!/usr/bin/python$|&2|" \
$pkgdir/usr/share/anjuta/project/{pygtk,python}/src/main.py
}
|
