blob: 18a040887d53f97622260ebb27c5871ae021b65a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# $Id: PKGBUILD 186137 2013-05-21 08:51:28Z heftig $
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Harley Laue <losinggeneration@yahoo.com>
pkgbase=anjuta
pkgname=('libanjuta' 'anjuta')
pkgver=3.8.3
pkgrel=1
pkgdesc="GNOME Integrated Development Environment (IDE)"
arch=(i686 x86_64)
license=(GPL)
makedepends=(gdl vte3 autogen devhelp glade libgda subversion gnome-icon-theme vala dconf
gtk-doc yelp-tools gnome-common intltool gobject-introspection itstool gjs
python)
url="http://www.anjuta.org/"
options=('!libtool' '!emptydirs')
source=(ftp://ftp.gnome.org/pub/gnome/sources/$pkgbase/${pkgver%.*}/$pkgbase-$pkgver.tar.xz)
sha256sums=('06afea1de911067419b774eda2548a729668f93c5463726b353f5db686493f95')
build() {
cd "$pkgbase-$pkgver"
./autogen.sh --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --enable-glade-catalog --enable-compile-warnings=minimum
make
}
package_libanjuta(){
pkgdesc="Anjuta runtime library"
depends=(gdl)
conflicts=('anjuta<3.4.4')
cd "$pkgbase-$pkgver/libanjuta"
# j1: Race during linking
make -j1 DESTDIR="$pkgdir" install
}
package_anjuta(){
pkgdesc="GNOME Integrated Development Environment (IDE)"
depends=(libanjuta vte3 autogen devhelp glade libgda subversion gnome-icon-theme vala dconf)
groups=('gnome-extra')
install=anjuta.install
cd "$pkgbase-$pkgver"
make -j1 DESTDIR="$pkgdir" install
cd libanjuta
make -j1 DESTDIR="$pkgdir" uninstall
}
|
