blob: 6b289393c9c9f5a19b5c61c1214003f4019746dd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# $Id: PKGBUILD 195314 2013-09-30 10:28:34Z allan $
# Maintainer: Rémy Oudompheng <remy@archlinux.org>
# Contributor: Firmicus <francois.archlinux.org>
# Contributor: bender02 at gmx dot com
pkgname=asymptote
pkgver=2.24
pkgrel=2
pkgdesc="A vector graphics language (like metapost)"
arch=('i686' 'x86_64')
url="http://asymptote.sourceforge.net/"
license=("GPL3")
depends=('texlive-core' 'gc' 'freeglut' 'glu' 'gsl' 'fftw' 'libsigsegv')
makedepends=('ghostscript' 'imagemagick'
'mesa' # For OpenGL headers
'texlive-plainextra' # For texinfo
)
optdepends=('python2: for the xasy GUI'
'python2-pillow: for the xasy GUI'
'tix: for the xasy GUI')
source=(http://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-${pkgver}.src.tgz)
install=texlive.install
sha1sums=('26dd0f4a36af0bc1d007d89ec7280ca55e9ed368')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --enable-gc=/usr \
--prefix=/usr \
--with-latex=/usr/share/texmf/tex/latex \
--with-context=/usr/share/texmf/tex/context \
--enable-offscreen
make all
}
check() {
cd "${srcdir}/${pkgname}-${pkgver}"
make check-all
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make -j1 DESTDIR="${pkgdir}" install-all
sed -i -e 's@env python@env python2@' ${pkgdir}/usr/share/asymptote/GUI/*.py
# this dir contains png files that are already embedded in the pdf documentation:
rm -rf ${pkgdir}/usr/share/info/asymptote
}
|
