blob: d338756737994147e396b08a06184cb9d8108acd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# $Id: PKGBUILD 127783 2011-06-18 10:36:42Z remy $
# Maintainer: Rémy Oudompheng <remy@archlinux.org>
# Contributor: Firmicus <francois.archlinux.org>
# Contributor: bender02 at gmx dot com
pkgname=asymptote
pkgver=2.11
pkgrel=1
pkgdesc="A vector graphics language (like metapost)"
arch=('i686' 'x86_64')
url="http://asymptote.sourceforge.net/"
license=("GPL3")
depends=('texlive-core' 'gc' 'freeglut' 'gsl' 'fftw')
makedepends=('ghostscript' 'imagemagick')
optdepends=('python2: for the xasy GUI'
'python-imaging: for the xasy GUI'
'tix: for the xasy GUI')
source=(http://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-${pkgver}.src.tgz)
install=texlive.install
sha1sums=('fde16f05bddb9e86a4dd05f25369f35c771fb84b')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --enable-gc=/usr \
--prefix=/usr \
--with-latex=/usr/share/texmf/tex/latex \
--with-context=/usr/share/texmf/tex/context
make all
}
check() {
cd "${srcdir}/${pkgname}-${pkgver}"
make check-all
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install-all
sed -i -e 's@env python@env python2@' ${pkgdir}/usr/share/asymptote/GUI/*.py
# this dir contains png files that are already embedded in the pdf documentation:
rm -rf ${pkgdir}/usr/share/info/asymptote
}
|
