blob: 6c1d840d933be7b7d25d98d9e5285efd0134cbd4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# $Id: PKGBUILD 141668 2011-11-02 03:17:12Z eric $
# Maintainer: Daniel Isenmann <daniel@archlinux.org>
# Contributor: György Balló <ballogy@freestart.hu>
pkgname=banshee
pkgver=2.6.1
pkgrel=1
pkgdesc="Music management and playback for GNOME"
arch=('i686' 'x86_64')
url="http://banshee.fm/"
license=('MIT')
depends=(libxxf86vm gstreamer0.10-base-plugins mono-addins dbus-sharp-glib boo libwebkit libsoup-gnome gdata-sharp taglib-sharp gudev-sharp gkeyfile-sharp gconf-sharp libmtp libgpod mono-zeroconf desktop-file-utils hicolor-icon-theme xdg-utils media-player-info gstreamer0.10-bad-plugins mono-upnp)
makedepends=('intltool' 'gnome-doc-utils' 'gtk-sharp-beans' 'gnome-common')
optdepends=('gstreamer0.10-good-plugins: Extra media codecs'
'gstreamer0.10-ugly-plugins: Extra media codecs'
'gstreamer0.10-ffmpeg: Extra media codecs'
'brasero: CD burning')
options=('!libtool')
install=$pkgname.install
source=(http://download.gnome.org/sources/$pkgname/2.6/$pkgname-$pkgver.tar.xz)
md5sums=('3c7775eecc079a018c468e9b4ab6cbe3')
build() {
export MONO_SHARED_DIR="$srcdir/.wabi"
mkdir -p "$MONO_SHARED_DIR"
cd "$srcdir/$pkgname-$pkgver"
./autogen.sh --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--disable-docs \
--disable-static \
--disable-scrollkeeper \
--disable-schemas-install \
--with-vendor-build-id=ArchLinux
make
}
package() {
export MONO_SHARED_DIR="$srcdir/.wabi"
mkdir -p "$MONO_SHARED_DIR"
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
install -D -m644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}
|
