blob: 3d3f31c46c3f352fb4c583f7240f89d989a27804 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
# $Id: PKGBUILD 146412 2012-01-10 21:47:26Z andrea $
# Maintainer:
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Geoffroy Carrier <geoffroy@archlinux.org>
pkgname=bluez
pkgver=4.97
pkgrel=1
pkgdesc="Libraries and tools for the Bluetooth protocol stack"
url="http://www.bluez.org/"
arch=('i686' 'x86_64')
license=('GPL2')
depends=('dbus-core')
makedepends=('gstreamer0.10-base' 'libusb-compat' 'libnl' 'libsndfile')
optdepends=("gstreamer0.10-base: bluetooth GStreamer support"
"alsa-lib: Audio bluetooth devices support"
"dbus-python: to run bluez-simple-agent"
"pygobject: to run bluez-simple-agent"
"libusb-compat: USB adapters support"
"cups: CUPS backend"
"libnl: netlink plugin")
conflicts=('bluez-libs' 'bluez-utils')
provides=('bluez-libs' 'bluez-utils')
replaces=('bluez-libs' 'bluez-utils')
options=('!libtool' 'emptydirs')
backup=(etc/bluetooth/{main,rfcomm,audio,network,input,serial}.conf
'etc/conf.d/bluetooth' 'etc/dbus-1/system.d/bluetooth.conf')
source=("http://www.kernel.org/pub/linux/bluetooth/${pkgname}-${pkgver}.tar.bz2"
'bluetooth.conf.d'
'rc.bluetooth'
'make-libcheck-optional.patch')
md5sums=('b302cee7f9b9527d29775449d7e1dfe6'
'7412982b440f29fa7f76a41a87fef985'
'8f9498707f809506928b2e480d3b6789'
'f112fc5bcaeecc7b6ea994f14786e235')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -p1 -i "${srcdir}"/make-libcheck-optional.patch
autoreconf -i -f
./configure --prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--libexecdir=/lib \
--enable-gstreamer \
--enable-alsa \
--enable-usb \
--enable-tools \
--enable-bccmd \
--enable-dfutool \
--enable-hid2hci \
--enable-hidd \
--enable-pand \
--enable-dund \
--enable-cups \
--enable-wiimote \
--disable-test
make
}
package() {
cd ${srcdir}/${pkgname}-${pkgver}
make DESTDIR=${pkgdir} install
install -Dm755 ${srcdir}/rc.bluetooth ${pkgdir}/etc/rc.d/bluetooth
install -d ${pkgdir}/etc/bluetooth
install -m644 network/network.conf \
input/input.conf \
audio/audio.conf \
serial/serial.conf \
${pkgdir}/etc/bluetooth/
install -Dm644 ${srcdir}/bluetooth.conf.d \
${pkgdir}/etc/conf.d/bluetooth
# FS#27630
install -Dm755 test/simple-agent "${pkgdir}"/usr/bin/bluez-simple-agent
install -Dm755 test/test-device "${pkgdir}"/usr/bin/bluez-test-device
install -Dm755 test/test-input "${pkgdir}"/usr/bin/bluez-test-input
sed -i 's#/usr/bin/python#/usr/bin/python2#' \
"${pkgdir}"/usr/bin/bluez-simple-agent \
"${pkgdir}"/usr/bin/bluez-test-device \
"${pkgdir}"/usr/bin/bluez-test-input
# http://mailman.archlinux.org/pipermail/arch-general/2011-April/019787.html
rm "${pkgdir}"/lib/udev/rules.d/97-bluetooth.rules
}
|
