blob: 951a2cf9553946bc203c8fb7a4fb43e09d2b6ec8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
|
# $Id: PKGBUILD 214184 2014-06-04 12:03:07Z tpowa $
# Maintainer: Tobias Powalowski <tpowa@archlinux.org>
pkgname=cifs-utils
pkgver=6.3
pkgrel=1
pkgdesc="CIFS filesystem user-space tools"
arch=(i686 x86_64)
url="http://wiki.samba.org/index.php/LinuxCIFS_utils"
license=('GPL')
depends=('libcap-ng' 'keyutils' 'krb5' 'talloc' 'libwbclient' 'pam')
source=(ftp://ftp.samba.org/pub/linux-cifs/cifs-utils/$pkgname-$pkgver.tar.bz2)
build() {
cd "$srcdir/$pkgname-$pkgver"
# systemd support is broken in mount.cifs
# https://bugs.archlinux.org/task/30958
./configure --prefix=/usr --sbindir=/usr/bin --disable-systemd
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" ROOTSBINDIR=/usr/bin install
mkdir -p $pkgdir/etc/request-key.d
install -m 644 contrib/request-key.d/cifs.idmap.conf $pkgdir/etc/request-key.d
install -m 644 contrib/request-key.d/cifs.spnego.conf $pkgdir/etc/request-key.d
# set mount.cifs uid, to enable none root mounting form fstab
chmod +s $pkgdir/usr/bin/mount.cifs
}
md5sums=('93697dbc043cb4d5c66e15e281f872e5')
|
