blob: 4c6f7e9b4743209ff3fbb2e8ce7310c6d4c21fd1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# $Id: PKGBUILD 194640 2013-09-20 02:05:29Z bisson $
# Contributor: Dale Blount <dale@archlinux.org>
# Contributor: Gregor Ibic <gregor.ibic@intelicom.si>
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
pkgname=clamav
pkgver=0.98
pkgrel=1
pkgdesc='Anti-virus toolkit for Unix'
url='http://www.clamav.net/'
license=('GPL')
options=('!libtool')
arch=('i686' 'x86_64')
depends=('bzip2' 'libltdl')
backup=('etc/logrotate.d/clamav')
source=("http://downloads.sourceforge.net/project/${pkgname}/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz"
'service'
'service.fresh'
'logrotate'
'tmpfiles.d'
'config.patch')
sha1sums=('1e6a7284721387646c713a8d32fa8b5a897985db'
'b6ac0c5de1e5b41232b10d4f84e86201c370eaeb'
'cda9a087e5593992150cb456e34c5f6f589aca82'
'bb488a56b0f6a0760446cde89c1e3321e2717b78'
'a224ea9b4d0f4f196827347d54bed51e11c197ea'
'00dfadd93d11186793cb1161745f9dd7370beb99')
install=install
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
patch -p1 -i ../config.patch
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure \
--prefix=/usr \
--sbindir=/usr/bin \
--sysconfdir=/etc/clamav \
--with-dbdir=/var/lib/clamav \
--disable-clamav \
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -Dm644 ../service.fresh "${pkgdir}"/usr/lib/systemd/system/freshclamd.service
install -Dm644 ../service "${pkgdir}"/usr/lib/systemd/system/clamd.service
install -Dm644 ../tmpfiles.d "${pkgdir}"/usr/lib/tmpfiles.d/clamav.conf
install -Dm644 ../logrotate "${pkgdir}"/etc/logrotate.d/clamav
install -d -o 64 -g 64 "${pkgdir}"/run/clamav
install -d -o 64 -g 64 "${pkgdir}"/var/log/clamav
install -d -o 64 -g 64 "${pkgdir}"/var/lib/clamav
}
|
