blob: 256f9e97085fcd06fbabee3ef5bf12910ae68509 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# $Id: PKGBUILD 214189 2014-06-04 13:50:46Z bluewind $
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
pkgname=claws-mail
pkgver=3.10.0
pkgrel=2
pkgdesc="A GTK+ based e-mail client."
arch=('i686' 'x86_64')
license=('GPL3')
url="http://www.claws-mail.org"
depends=('gtk2' 'gnutls' 'startup-notification' 'enchant' 'gpgme' 'libetpan' 'compface'
'libsm' 'dbus-glib' 'hicolor-icon-theme' 'desktop-file-utils')
makedepends=('spamassassin' 'bogofilter' 'valgrind'
# dependencies for plugins
'libsoup' 'libgdata' 'webkitgtk2' 'libnotify' 'libcanberra' 'poppler-glib' 'pygtk')
#'libchamplain' needed for geolocation plugin, disabled for now - most time it's not compatible with current gnome releases
optdepends=('python2: needed for some tools and python plugin'
'perl: needed for some tools and perl plugin'
'spamassassin: adds support for spamfiltering'
'bogofilter: adds support for spamfiltering'
'libnotify: for notification plugin'
'libcanberra: for notification plugin'
'dbus: for notification plugin'
'libxml2: for gtkhtml2_viewer and rssyl plugins'
'curl: for gtkhtml2_viewer, vcalendar, rssyl and spamreport plugins'
'libarchive: for archive plugin and various other plugins'
'libytnef: for tnef_parse plugin'
'webkitgtk2: for the fancy webkit html plugin'
'libsoup: for the fancy webkit html plugin'
'libgdata: for gdata plugin'
'poppler-glib: for pdf viewer plugin'
'ghostscript: for pdf viewer plugin')
replaces=('sylpheed-claws' 'claws-mail-extra-plugins')
conflicts=('claws-mail-extra-plugins')
provides=('claws')
install=claws-mail.install
source=(http://downloads.sourceforge.net/sourceforge/claws-mail/${pkgname}-${pkgver}.tar.xz{,.asc})
sha1sums=('c5e8063ea922b1bd6825f5221347ec8ebfa0ae3b'
'SKIP')
build() {
cd ${pkgname}-${pkgver}
# fixes for python2
export PYTHON="/usr/bin/python2"
sed -i 's@^#!.*python.*@#!/usr/bin/python2@' tools/*.py
sed -i 's:python -c:python2 -c:g' configure
./configure --prefix=/usr --disable-static \
--enable-enchant \
--enable-gnutls \
--enable-ldap \
--enable-crash-dialog \
--enable-pgpmime-plugin \
--enable-spamassassin-plugin \
--enable-bogofilter-plugin \
#--help
make
}
package() {
cd ${pkgname}-${pkgver}
make DESTDIR=${pkgdir} install
# build and install extra tools
cd tools
make
# all executables and .conf files ; only top directory
find -maxdepth 1 -type f -and -perm /111 -or -name '*.conf' | while read i ; do
install -D -m755 ${i} \
${pkgdir}/usr/lib/claws-mail/tools/${i}
done
}
|
