blob: 5dac6abe429be9cc091980b25674b91e77d4a41c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# $Id: PKGBUILD 112888 2011-03-07 14:35:42Z paul $
# Maintainer: Paul Mattal <paul@archlinux.org>
# Contributor: Andrew Wright <andreww@photism.org>
# Contributor: Andreas W. Hauser <andy-aur@splashground.de>
pkgname=eclipse
pkgver=3.6.2
_internal_pkgver=3.6.2
pkgrel=1
_date=201102101200
pkgdesc="An IDE for Java and other languages"
arch=('i686' 'x86_64')
url="http://eclipse.org"
depends=('java-environment' 'gtk2' 'unzip' 'xulrunner')
install=${pkgname}.install
makedepends=('zip')
license=("EPL/1.1")
source=("ftp://ftp.osuosl.org/pub/eclipse/eclipse/downloads/drops/R-${pkgver}-${_date}/${pkgname}-SDK-${pkgver}-linux-gtk.tar.gz"
'eclipse.svg' 'eclipse.sh' 'eclipse.desktop'
'eclipse.ini.patch')
md5sums=('7777a21debf1e05591731ac5c93b6bb6'
'77cff7543ccf7e177cb6667f5a20ce19'
'7ea99a30fbaf06ec29261541b8eb1e23'
'ba8a37e30a7ebd69774cec87c69e8c44'
'017b2a68edc48a752a7e27c7aceef797')
[ "$CARCH" = "x86_64" ] && source[0]="ftp://ftp.osuosl.org/pub/eclipse/eclipse/downloads/drops/R-${pkgver}-${_date}/${pkgname}-SDK-${pkgver}-linux-gtk-${CARCH}.tar.gz"
[ "$CARCH" = "x86_64" ] && md5sums[0]='b82be4ed2dabf9dc53188b9dc3891f32'
package() {
cd "${srcdir}/eclipse"
# patch to increase default memory limits
patch -Np1 -i "${srcdir}/eclipse.ini.patch"
# install eclipse
install -m755 -d "${pkgdir}/usr/share"
mv "${srcdir}/eclipse" "${pkgdir}/usr/share/"
# install misc
install -d ${pkgdir}/usr/bin ${pkgdir}/usr/share/applications \
${pkgdir}/usr/share/icons/hicolor/{16x16,32x32,48x48}/apps
install -m755 "${srcdir}/eclipse.sh" "${pkgdir}/usr/bin/eclipse"
install -m644 "${srcdir}/eclipse.desktop" "${pkgdir}/usr/share/applications/"
ln -s /usr/share/eclipse/plugins/org.eclipse.sdk_${_internal_pkgver}.v${_date}/eclipse.png \
"${pkgdir}/usr/share/icons/hicolor/16x16/apps/eclipse.png"
ln -s /usr/share/eclipse/plugins/org.eclipse.sdk_${_internal_pkgver}.v${_date}/eclipse32.png \
"${pkgdir}/usr/share/icons/hicolor/32x32/apps/eclipse.png"
ln -s /usr/share/eclipse/plugins/org.eclipse.sdk_${_internal_pkgver}.v${_date}/eclipse48.png \
"${pkgdir}/usr/share/icons/hicolor/48x48/apps/eclipse.png"
# install icon
install -Dm644 ${srcdir}/eclipse.svg \
${pkgdir}/usr/share/icons/hicolor/scalable/apps/eclipse.svg
# fix python 2.7 path
sed -i 's|#!/usr/bin/python|#!/usr/bin/python2|' \
${pkgdir}/usr/share/eclipse/plugins/org.apache.ant_1.7.1.v20100518-1145/bin/runant.py
}
|
