blob: 59fe84bd5b115d98493c1752111980b86c5195ab (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# $Id: PKGBUILD 206354 2014-02-24 10:37:56Z bpiotrowski $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Maintainer: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>
# Contributor: Paul Mattal <paul@archlinux.org>
pkgname=ffmpeg
pkgver=2.1.4
pkgrel=1
epoch=1
pkgdesc='Complete and free Internet live audio and video broadcasting solution'
arch=('i686' 'x86_64')
url='http://ffmpeg.org/'
license=('GPL')
depends=(
'alsa-lib' 'bzip2' 'fontconfig' 'gnutls' 'gsm' 'lame' 'libass'
'libbluray' 'libmodplug' 'libpulse' 'libtheora' 'libva' 'libvorbis' 'libvpx'
'opencore-amr' 'openjpeg' 'opus' 'rtmpdump' 'schroedinger' 'sdl' 'speex'
'v4l-utils' 'x264' 'xvidcore' 'zlib'
)
makedepends=('libvdpau' 'yasm')
source=(http://ffmpeg.org/releases/$pkgname-$pkgver.tar.bz2)
md5sums=('dedc28003a77c69432c42ab16e5f6982')
build() {
cd $pkgname-$pkgver
./configure \
--prefix=/usr \
--disable-debug \
--disable-static \
--enable-avresample \
--enable-dxva2 \
--enable-fontconfig \
--enable-gnutls \
--enable-gpl \
--enable-libass \
--enable-libbluray \
--enable-libfreetype \
--enable-libgsm \
--enable-libmodplug \
--enable-libmp3lame \
--enable-libopencore_amrnb \
--enable-libopencore_amrwb \
--enable-libopenjpeg \
--enable-libopus \
--enable-libpulse \
--enable-librtmp \
--enable-libschroedinger \
--enable-libspeex \
--enable-libtheora \
--enable-libv4l2 \
--enable-libvorbis \
--enable-libvpx \
--enable-libx264 \
--enable-libxvid \
--enable-pic \
--enable-postproc \
--enable-runtime-cpudetect \
--enable-shared \
--enable-swresample \
--enable-vdpau \
--enable-version3 \
--enable-x11grab
make
make tools/qt-faststart
make doc/ff{mpeg,play,server}.1
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install install-man
install -Dm755 tools/qt-faststart "$pkgdir"/usr/bin/qt-faststart
}
# vim:set ts=2 sw=2 et:
|
