blob: a1e52baf9c9ef7031e8712674833eb413099adbd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# $Id: PKGBUILD 138073 2011-09-16 03:35:31Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>
pkgname=foobillard++
pkgver=3.4beta
pkgrel=1
pkgdesc="An OpenGL billiard game"
arch=('i686' 'x86_64')
url="http://foobillardplus.sourceforge.net/"
license=('GPL2')
depends=('bzip2' 'freetype2' 'libpng' 'mesa' 'sdl_net')
replaces=('foobillard')
source=(http://downloads.sourceforge.net/foobillardplus/foobillardplus-${pkgver}.tar.gz)
md5sums=('130418a45ba84b4132f9b27712feb919')
sha1sums=('d8723568e460ee62cb913b0c8d7c9a9f557395ee')
build() {
cd "${srcdir}/foobillardplus-${pkgver}"
sed -i 's|$prefix/foobillardplus|$prefix|' configure
sed -i 's|$prefix/data|$prefix/share/foobillardplus|' configure
sed -i 's|"/data"|"/share/foobillardplus"|' src/language.c
sed -i 's|/opt/foobillardplus/bin/||' foobillardplus.desktop
sed -i 's|/opt/foobillardplus/||' foobillardplus.desktop
./configure --prefix=/usr
make
}
package() {
cd "${srcdir}/foobillardplus-${pkgver}"
install -Dm755 src/foobillardplus "${pkgdir}/usr/bin/foobillardplus"
install -d "${pkgdir}/usr/share/foobillardplus"
cp -R data/* "${pkgdir}/usr/share/foobillardplus"
install -Dm644 foobillardplus.desktop "${pkgdir}/usr/share/applications/foobillardplus.desktop"
install -Dm644 foobillardplus.png "${pkgdir}/usr/share/pixmaps/foobillardplus.png"
install -Dm644 foobillardplus.xbm "${pkgdir}/usr/share/pixmaps/foobillardplus.xbm"
find "${pkgdir}" -depth -type d -name .svn -exec rm -rf {} \;
}
|
